Support halve(eachindex(string)) (#64)

Author: tkf

src/implementations.jl

@@ -64,6 +64,30 @@ safelength(xs) =
 
 amount(xs) = length(xs)
 amount(xs::AbstractString) = lastindex(xs) - firstindex(xs) + 1
+amount(xs::Base.EachStringIndex) = amount(xs.s)
+
+struct WithOffset{Iter,Offset}
+    iter::Iter
+    offset::Offset
+end
+
+withoffset(iter, offset) = WithOffset(iter, offset)
+withoffset(iter::WithOffset, offset) = WithOffset(iter.iter, iter.offset + offset)
+
+_shift(wo, ::Nothing) = nothing
+_shift(wo, (i, s)) = (convert(eltype(wo), wo.offset + i), s)
+Base.iterate(wo::WithOffset) = _shift(wo, iterate(wo.iter))
+Base.iterate(wo::WithOffset, s) = _shift(wo, iterate(wo.iter, s))
+
+Base.IteratorEltype(::Type{<:WithOffset{Iter}}) where {Iter} =
+    Base.IteratorEltype(Iter)
+Base.IteratorSize(::Type{<:WithOffset{Iter}}) where {Iter} =
+    Base.IteratorSize(Iter)
+Base.eltype(::Type{WithOffset{Iter,Offset}}) where {Iter,Offset} =
+    promote_type(eltype(Iter), Offset)
+Base.length(wo::WithOffset) = length(wo.iter)
+Base.size(wo::WithOffset) = size(wo.iter)
+amount(wo::WithOffset) = amount(wo.offset)
 
 function halve(xs::AbstractVector)
     mid = length(xs) ÷ 2
@@ -172,6 +196,20 @@ function halve(xs::AbstractString)
     return (left, right)
 end
 
+function halve(xs::Base.EachStringIndex)
+    offset = firstindex(xs.s) - 1
+    mid = thisind(xs.s, (lastindex(xs.s) - offset) ÷ 2 + offset)
+    mid2 = nextind(xs.s, mid)
+    left = eachindex(SubString(xs.s, firstindex(xs.s):mid))
+    right = withoffset(eachindex(SubString(xs.s, mid2:lastindex(xs.s))), mid2 - 1)
+    return (left, right)
+end
+
+function halve(xs::WithOffset{<:Base.EachStringIndex})
+    left, right = halve(xs.iter)
+    return withoffset(left, xs.offset), withoffset(right, xs.offset)
+end
+
 @generated function halve(xs::NTuple{N,Any}) where {N}
     m = N ÷ 2
     quote

test/test_halve.jl

@@ -33,6 +33,14 @@ pairs(adjoint(reshape(1:6, 2, 3)))
 "あいうえおか"
 "aいυe𝒐"
 "aいυe𝒐か"
+eachindex("abcde")
+eachindex("abcdef")
+eachindex("αβγδϵ")
+eachindex("αβγδϵζ")
+eachindex("あいうえお")
+eachindex("あいうえおか")
+eachindex("aいυe𝒐")
+eachindex("aいυe𝒐か")
 (1, 2, 3, 4, 5)
 (1, 2, 3, 4, 5, 6)
 (a=1, b=2, c=3, d=4, e=5)

test/test_withoffset.jl

@@ -0,0 +1,27 @@
+module TestWithOffset
+
+using Base: HasEltype, HasLength, HasShape, IteratorEltype, IteratorSize
+using SplittablesBase.Implementations: WithOffset
+using Test
+
+@testset "eltype" begin
+    @test IteratorEltype(WithOffset(1:2, 0)) isa HasEltype
+    @test eltype(WithOffset(1:2, Int128(0))) === Int128
+end
+
+@testset "size" begin
+    xs = eachindex("abc")
+    @test IteratorSize(WithOffset(xs, 1)) isa HasLength
+    @test length(WithOffset(xs, 1)) == 3
+    @test collect(WithOffset(xs, 1)) == xs .+ 1
+end
+
+@testset "size" begin
+    xs = reshape(1:6, 2, 3)
+    @test IteratorSize(WithOffset(xs, 0)) isa HasShape
+    @test size(WithOffset(xs, 1)) == (2, 3)
+    @test length(WithOffset(xs, 1)) == 6
+    @test collect(WithOffset(xs, 1)) == xs .+ 1
+end
+
+end  # module