build.gradle

import java.util.stream.Collector
import java.util.stream.Collectors

buildscript {
    repositories {
        mavenCentral()
        maven { url 'https://repo.spring.io/plugins-release' }
        maven { url "https://plugins.gradle.org/m2/" }

        maven { url 'https://repo.spring.io/snapshot' }


    }
    dependencies {
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.30.0"
        classpath "de.marcphilipp.gradle:nexus-publish-plugin:0.4.0"
        classpath "net.ltgt.gradle:gradle-errorprone-plugin:${gradleErrorPronePluginVersion}"
    }
}


allprojects { pr ->
    pr['signing.keyId'] = System.getenv('GPG_ID')
    pr['signing.password'] = System.getenv('GPG_PASSWORD')
    pr['signing.secretKeyRingFile'] = '/home/travis/.gnupg/secring.gpg'


}
apply plugin: 'idea'
apply plugin: 'jacoco'
apply from: "${rootDir}/publishSonatype.gradle"


allprojects {
    repositories {
        mavenCentral()
        maven { url 'https://repo.spring.io/release' }
        maven { url "https://jitpack.io" }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
        maven { url 'https://repo.spring.io/snapshot' }
        maven { url "https://repo.spring.io/milestone" }

    }
}

subprojects {

    apply plugin: 'java'
    apply plugin: 'jacoco'
    apply plugin: 'net.ltgt.errorprone'


    tasks.withType(JavaCompile, {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    })


    tasks.withType(Test) {
        //forkEvery = 1
        testLogging {
            exceptionFormat = 'full'
            //  showStandardStreams = true
        }
    }


    dependencies {
        ["annotationProcessor", "testAnnotationProcessor", "compileOnly", "testCompileOnly"].each { conf ->
            add(conf, "org.projectlombok:lombok:${lombokVersion}")
        }
        errorprone("com.google.errorprone:error_prone_core:${errorProneVersion}")
    }
    tasks.withType(JavaCompile).configureEach {
        options.errorprone.disableWarningsInGeneratedCode = true

        options.errorprone.enabled = false
        // (it.name.startsWith("compile") && it.name.endsWith("TestJava") ) ? false:(null != System.getenv("CI"))


    }
    configurations.all {
        resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
    }

}

task codeCoverageReport(type: JacocoReport) {
    executionData fileTree(project.rootDir.absolutePath).include("**/build/jacoco/*.exec")

    sourceSets(project('grpc-spring-boot-starter').sourceSets.main
            , project('grpc-client-spring-boot-starter').sourceSets.main)

    reports {
        xml.required.set(true)
        xml.getOutputLocation().set(getLayout().getBuildDirectory().file("reports/jacoco/report.xml"))
        html.required.set(true)
        csv.required.set(true)
    }
    dependsOn {
        subprojects.stream().flatMap { p ->
            p.getTasks()
                     .getAsMap()
                     .entrySet()
                     .stream()
                     .filter {[ "delombok","javadoc"].contains(it.key) || it.value instanceof Test }
                     .map {it.value}
        }.collect(Collectors.toList())
    }
}


subprojects {
    tasks.withType(Test, { t ->
        t.environment.put("TESTCONTAINERS_REUSE_ENABLE", "true")
    })
}