tectonic-with-biber: init wrapper

This is a simple `symlinkJoin` wrapper that bundles tectonic with
`biber-for-tectonic`. This is partially is recovered from:

  5aa8e9f

Also, set @bryango as maintainer.

Co-authored-by: Doron Behar <[email protected]>

Author: bryango

pkgs/tools/typesetting/tectonic/wrapper.nix

@@ -0,0 +1,52 @@
+{ lib
+, makeBinaryWrapper
+, symlinkJoin
+, tectonic
+, biber-for-tectonic
+, biber
+}:
+
+let
+
+  pname = "tectonic-with-biber";
+  inherit (biber-for-tectonic) version;
+
+  # manually construct `name` for `symlinkJoin`
+  name = "${pname}-${version}";
+
+  meta = tectonic.meta // {
+    inherit name;
+    description = "Tectonic, wrapped with the correct biber version";
+    longDescription = ''
+      This package wraps tectonic with biber without triggering rebuilds.
+      The biber executable is exposed with a version suffix, such as
+      `biber-${version}`, to prevent conflict with the `biber` bundled with
+      texlive in nixpkgs.
+
+      This serves as a downstream fix for:
+      - https://github.com/tectonic-typesetting/tectonic/issues/893
+    '';
+    maintainers = with lib.maintainers; [ bryango ];
+  };
+
+in
+
+symlinkJoin {
+
+  inherit pname version name meta;
+
+  paths = [ tectonic ];
+  nativeBuildInputs = [ makeBinaryWrapper ];
+  passthru = { inherit biber; };
+
+  # tectonic runs biber when it detects it needs to run it, see:
+  # https://github.com/tectonic-typesetting/tectonic/releases/tag/tectonic%400.7.0
+  postBuild = ''
+    wrapProgram $out/bin/tectonic \
+      --prefix PATH : "${lib.getBin biber-for-tectonic}/bin"
+    makeBinaryWrapper "${lib.getBin biber-for-tectonic}/bin/biber" \
+      $out/bin/biber-${biber-for-tectonic.version}
+  '';
+  # the biber executable is exposed as `biber-${biber.version}`
+
+}

pkgs/top-level/all-packages.nix

@@ -25336,6 +25336,8 @@ with pkgs;
     harfbuzz = harfbuzzFull;
   };
 
+  tectonic-with-biber = callPackage ../tools/typesetting/tectonic/wrapper.nix { };
+
   tepl = callPackage ../development/libraries/tepl { };
 
   termbench-pro = callPackage ../development/libraries/termbench-pro { fmt = fmt_8; };