gcc_avr_toolchain.cmake

GET_FILENAME_COMPONENT(THIS_FILE_DIR ${CMAKE_CURRENT_LIST_FILE} DIRECTORY)
set(CMAKE_MODULE_PATH ${THIS_FILE_DIR} ${CMAKE_MODULE_PATH})

##########################################################################
# "THE ANY BEVERAGE-WARE LICENSE" (Revision 42 - based on beer-ware
# license):
# <dev@layer128.net> wrote this file. As long as you retain this notice
# you can do whatever you want with this stuff. If we meet some day, and
# you think this stuff is worth it, you can buy me a be(ve)er(age) in
# return. (I don't like beer much.)
#
# Matthias Kleemann
##########################################################################

##########################################################################
# The toolchain requires some variables set.
#
# AVR_MCU (default: atmega8)
#     the type of AVR the application is built for
# AVR_L_FUSE (NO DEFAULT)
#     the LOW fuse value for the MCU used
# AVR_H_FUSE (NO DEFAULT)
#     the HIGH fuse value for the MCU used
# AVR_UPLOADTOOL (default: avrdude)
#     the application used to upload to the MCU
#     NOTE: The toolchain is currently quite specific about
#           the commands used, so it needs tweaking.
# AVR_UPLOADTOOL_PORT (default: usb)
#     the port used for the upload tool, e.g. usb
# AVR_PROGRAMMER (default: avrispmkII)
#     the programmer hardware used, e.g. avrispmkII
##########################################################################

##########################################################################
# options
##########################################################################
option(WITH_MCU "Add the MCU type to the target file name." ON)

##########################################################################
# executables in use
##########################################################################
find_program(AVR_CC avr-gcc)
find_program(AVR_CXX avr-g++)
find_program(AVR_OBJCOPY avr-objcopy)
find_program(AVR_SIZE_TOOL avr-size)
find_program(AVR_OBJDUMP avr-objdump)

##########################################################################
# toolchain starts with defining mandatory variables
##########################################################################
set(CMAKE_SYSTEM_NAME Generic)
set(CMAKE_SYSTEM_PROCESSOR avr)
set(CMAKE_C_COMPILER ${AVR_CC})
set(CMAKE_CXX_COMPILER ${AVR_CXX})

##########################################################################
# Identification
##########################################################################
set(AVR 1)

##########################################################################
# some necessary tools and variables for AVR builds, which may not be
# defined yet
# - AVR_UPLOADTOOL
# - AVR_UPLOADTOOL_PORT
# - AVR_PROGRAMMER
# - AVR_MCU
# - AVR_SIZE_ARGS
##########################################################################

function (setup_gcc_avr_defaults)

  if (NOT AVR_UPLOADTOOL)
    set(AVR_UPLOADTOOL avrdude PARENT_SCOPE)
    find_program(AVR_UPLOADTOOL avrdude)
  endif ()

  if (NOT AVR_UPLOADTOOL_PORT)
    set(AVR_UPLOADTOOL_PORT usb PARENT_SCOPE)
  endif ()

  if (NOT AVR_PROGRAMMER)
    set(AVR_PROGRAMMER usbtiny)
    set(AVR_PROGRAMMER ${AVR_PROGRAMMER} PARENT_SCOPE)
  endif ()

  if (NOT AVR_MCU)
    set(AVR_MCU atmega2560)
    set(AVR_MCU atmega2560 PARENT_SCOPE)
  endif ()

  if (NOT AVR_SIZE_ARGS)
    if (APPLE)
      set(AVR_SIZE_ARGS -B PARENT_SCOPE)
    else (APPLE)
      set(AVR_SIZE_ARGS -C;--mcu=${AVR_MCU} PARENT_SCOPE)
    endif (APPLE)
  endif ()

  if (NOT AVR_UPLOADTOOL_BASE_OPTIONS)
    set(AVR_UPLOADTOOL_BASE_OPTIONS -D -v -p ${AVR_MCU} -c ${AVR_PROGRAMMER})
    set(AVR_UPLOADTOOL_BASE_OPTIONS ${AVR_UPLOADTOOL_BASE_OPTIONS} PARENT_SCOPE)
  endif ()

  if (AVR_UPLOADTOOL_BAUDRATE)
    set(AVR_UPLOADTOOL_BASE_OPTIONS ${AVR_UPLOADTOOL_BASE_OPTIONS} -b ${AVR_UPLOADTOOL_BAUDRATE}
      PARENT_SCOPE)
  endif ()

  ##########################################################################
  # check build types:
  # - Debug
  # - Release
  # - RelWithDebInfo
  #
  # Release is chosen, because of some optimized functions in the
  # AVR toolchain, e.g. _delay_ms().
  ##########################################################################
  if (NOT ((CMAKE_BUILD_TYPE MATCHES Release) OR
          (CMAKE_BUILD_TYPE MATCHES RelWithDebInfo) OR
          (CMAKE_BUILD_TYPE MATCHES Debug) OR
          (CMAKE_BUILD_TYPE MATCHES MinSizeRel)))
    set(CMAKE_BUILD_TYPE Release PARENT_SCOPE)
  endif ()

  ##########################################################################
  # target file name add-on
  ##########################################################################
  if (WITH_MCU)
    set(MCU_TYPE_FOR_FILENAME "-${AVR_MCU}" PARENT_SCOPE)
  else ()
    set(MCU_TYPE_FOR_FILENAME "" PARENT_SCOPE)
  endif ()

endfunction ()

##########################################################################
# add_avr_executable
# - IN_VAR: EXECUTABLE_NAME
#
# Creates targets and dependencies for AVR toolchain, building an
# executable. Calls add_executable with ELF file as target name, so
# any link dependencies need to be using that target, e.g. for
# target_link_libraries(<EXECUTABLE_NAME>-${AVR_MCU}.elf ...).
##########################################################################
function(add_avr_executable EXECUTABLE_NAME)
  if (NOT ARGN)
    message(FATAL_ERROR "No source files given for ${EXECUTABLE_NAME}.")
  endif(NOT ARGN)

  # set file names
  set(FPATH ${EXECUTABLE_OUTPUT_PATH})
  set(elf_file ${EXECUTABLE_NAME}${MCU_TYPE_FOR_FILENAME}.elf)
  set(hex_file ${FPATH}/${EXECUTABLE_NAME}${MCU_TYPE_FOR_FILENAME}.hex)
  set(lst_file ${FPATH}/${EXECUTABLE_NAME}${MCU_TYPE_FOR_FILENAME}.lst)
  set(map_file ${FPATH}/${EXECUTABLE_NAME}${MCU_TYPE_FOR_FILENAME}.map)
  set(eeprom_image ${FPATH}/${EXECUTABLE_NAME}${MCU_TYPE_FOR_FILENAME}-eeprom.hex)

  # elf file
  add_executable(${elf_file} EXCLUDE_FROM_ALL ${ARGN})

  set_target_properties(
    ${elf_file}
    PROPERTIES
      COMPILE_FLAGS "-mmcu=${AVR_MCU}"
      LINK_FLAGS "-mmcu=${AVR_MCU} -Wl,--gc-sections -mrelax -Wl,-Map,${map_file}"
  )

  add_custom_command(
    OUTPUT ${hex_file}
    COMMAND ${AVR_OBJCOPY} -j .text -j .data -O ihex ${FPATH}/${elf_file} ${hex_file}
    COMMAND ${AVR_SIZE_TOOL} ${AVR_SIZE_ARGS} ${FPATH}/${elf_file}
    DEPENDS ${elf_file}
  )

  add_custom_command(
    OUTPUT ${lst_file}
    COMMAND ${AVR_OBJDUMP} -d ${FPATH}/${elf_file} > ${lst_file}
    DEPENDS ${elf_file}
  )

  add_custom_command(
    OUTPUT ${eeprom_image}
    COMMAND
      ${AVR_OBJCOPY} -j .eeprom --set-section-flags=.eeprom=alloc,load
      --change-section-lma .eeprom=0 --no-change-warnings
      -O ihex ${FPATH}/${elf_file} ${eeprom_image}
    DEPENDS ${elf_file}
  )

  add_custom_target(
    ${EXECUTABLE_NAME}
    ALL
    DEPENDS ${hex_file} ${lst_file} ${eeprom_image}
  )

  set_target_properties(
    ${EXECUTABLE_NAME}
    PROPERTIES
      OUTPUT_NAME "${elf_file}"
  )

  add_custom_target(
    ${EXECUTABLE_NAME}-upload
    ${AVR_UPLOADTOOL} ${AVR_UPLOADTOOL_BASE_OPTIONS} ${AVR_UPLOADTOOL_OPTIONS}
      -P ${AVR_UPLOADTOOL_PORT}
      -U flash:w:${hex_file}
    DEPENDS ${hex_file}
    COMMENT "Uploading ${hex_file} to ${AVR_MCU} using ${AVR_PROGRAMMER}"
  )

  # upload eeprom only - with avrdude
  # see also bug http://savannah.nongnu.org/bugs/?40142
  add_custom_target(
    ${EXECUTABLE_NAME}-upload-eeprom
    ${AVR_UPLOADTOOL} ${AVR_UPLOADTOOL_BASE_OPTIONS} ${AVR_UPLOADTOOL_OPTIONS}
        -U eeprom:w:${eeprom_image}
        -P ${AVR_UPLOADTOOL_PORT}
    DEPENDS ${eeprom_image}
    COMMENT "Uploading ${eeprom_image} to ${AVR_MCU} using ${AVR_PROGRAMMER}"
  )

  add_custom_target(
    ${EXECUTABLE_NAME}-disassemble
    ${AVR_OBJDUMP} -h -S ${elf_file} > ${lst_file}.disa
    DEPENDS ${elf_file}
  )

  # clean
  get_directory_property(clean_files ADDITIONAL_MAKE_CLEAN_FILES)
  set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES "${map_file}")

endfunction (add_avr_executable)

##########################################################################
# add_avr_library
# - IN_VAR: LIBRARY_NAME
#
# Calls add_library with an optionally concatenated name
# <LIBRARY_NAME>${MCU_TYPE_FOR_FILENAME}.
# This needs to be used for linking against the library, e.g. calling
# target_link_libraries(...).
##########################################################################

function(add_avr_library LIBRARY_NAME)
  if (NOT ARGN)
    message(FATAL_ERROR "No source files given for ${LIBRARY_NAME}.")
  endif(NOT ARGN)

  set(lib_file ${LIBRARY_NAME}${MCU_TYPE_FOR_FILENAME})

  add_library(${lib_file} STATIC ${ARGN})

  set_target_properties(
    ${lib_file} PROPERTIES COMPILE_FLAGS "-mmcu=${AVR_MCU}" OUTPUT_NAME "${lib_file}")

  if (NOT TARGET ${LIBRARY_NAME})
    add_custom_target( ${LIBRARY_NAME} ALL DEPENDS ${lib_file})
    set_target_properties( ${LIBRARY_NAME} PROPERTIES OUTPUT_NAME "${lib_file}")
  endif ()

endfunction(add_avr_library)

##########################################################################
# avr_target_link_libraries
# - IN_VAR: EXECUTABLE_TARGET
# - ARGN  : targets and files to link to
#
# Calls target_link_libraries with AVR target names (concatenation,
# extensions and so on.
##########################################################################

function(avr_target_link_libraries EXECUTABLE_TARGET)
  if (NOT ARGN)
    message(FATAL_ERROR "Nothing to link to ${EXECUTABLE_TARGET}.")
  endif(NOT ARGN)

  get_target_property(TARGET_LIST ${EXECUTABLE_TARGET} OUTPUT_NAME)

  foreach (TGT ${ARGN})
    if (TARGET ${TGT})
      get_target_property(ARG_NAME ${TGT} OUTPUT_NAME)
      list(APPEND NON_TARGET_LIST ${ARG_NAME})
    else ()
      list(APPEND NON_TARGET_LIST ${TGT})
    endif ()
  endforeach ()

  target_link_libraries(${TARGET_LIST} ${NON_TARGET_LIST})

endfunction(avr_target_link_libraries EXECUTABLE_TARGET)

##########################################################################
# avr_target_include_directories
#
# Calls target_include_directories with AVR target names
##########################################################################

function(avr_target_include_directories EXECUTABLE_TARGET)
    if (NOT ARGN)
      message(FATAL_ERROR "No include directories to add to ${EXECUTABLE_TARGET}.")
    endif()

    get_target_property(TARGET_LIST ${EXECUTABLE_TARGET} OUTPUT_NAME)
    set(extra_args ${ARGN})

    target_include_directories(${TARGET_LIST} ${extra_args})
endfunction()

##########################################################################
# avr_target_compile_definitions
#
# Calls target_compile_definitions with AVR target names
##########################################################################

function(avr_target_compile_definitions EXECUTABLE_TARGET)
    if (NOT ARGN)
      message(FATAL_ERROR "No compile definitions to add to ${EXECUTABLE_TARGET}.")
    endif()

    get_target_property(TARGET_LIST ${EXECUTABLE_TARGET} OUTPUT_NAME)
    set(extra_args ${ARGN})

   target_compile_definitions(${TARGET_LIST} ${extra_args})
endfunction()

##########################################################################
# Get/set operating parameters 
##########################################################################

function(avr_generate_fixed_targets)
  # get status
  add_custom_target(
    get_status
    ${AVR_UPLOADTOOL} ${AVR_UPLOADTOOL_BASE_OPTIONS} -P ${AVR_UPLOADTOOL_PORT} -n -v
    COMMENT "Get status from ${AVR_MCU}"
  )
   
  # get fuses
  add_custom_target(
    get_fuses
    ${AVR_UPLOADTOOL} ${AVR_UPLOADTOOL_BASE_OPTIONS} -P ${AVR_UPLOADTOOL_PORT} -n
      -U lfuse:r:-:b
      -U hfuse:r:-:b
      -U efuse:r:-:b
    COMMENT "Get fuses from ${AVR_MCU}"
  )
  
  # set fuses
  add_custom_target(
    set_fuses
    ${AVR_UPLOADTOOL} ${AVR_UPLOADTOOL_BASE_OPTIONS} -P ${AVR_UPLOADTOOL_PORT}
      -U lfuse:w:${AVR_L_FUSE}:m
      -U hfuse:w:${AVR_H_FUSE}:m
      -U efuse:w:${AVR_E_FUSE}:m
    COMMENT "Setup: High Fuse: ${AVR_H_FUSE} Low Fuse: ${AVR_L_FUSE} Extended Fuse: ${AVR_E_FUSE}"
  )
  
  # get oscillator calibration
  add_custom_target(
    get_calibration
      ${AVR_UPLOADTOOL} ${AVR_UPLOADTOOL_BASE_OPTIONS} -P ${AVR_UPLOADTOOL_PORT}
      -U calibration:r:${AVR_MCU}_calib.tmp:r
    COMMENT "Write calibration status of internal oscillator to ${AVR_MCU}_calib.tmp."
  )
  
  # set oscillator calibration
  add_custom_target(
    set_calibration
    ${AVR_UPLOADTOOL} ${AVR_UPLOADTOOL_BASE_OPTIONS} -P ${AVR_UPLOADTOOL_PORT}
      -U calibration:w:${AVR_MCU}_calib.hex
    COMMENT "Program calibration status of internal oscillator from ${AVR_MCU}_calib.hex."
  )
endfunction()