CMakeLists.txt

cmake_minimum_required(VERSION 3.20 FATAL_ERROR)

project(libmeshSandbox
  VERSION 0.1
  LANGUAGES CXX
)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wpedantic")

include(FetchContent)

FetchContent_Declare(fmt
  GIT_REPOSITORY https://github.com/fmtlib/fmt.git
  GIT_TAG 11.0.2
)
FetchContent_MakeAvailable(fmt)

FetchContent_Declare(yaml-cpp
  GIT_REPOSITORY https://github.com/jbeder/yaml-cpp.git
  GIT_TAG yaml-cpp-0.7.0
)
FetchContent_MakeAvailable(yaml-cpp)

find_package(MPI REQUIRED)

find_package(PkgConfig REQUIRED)
pkg_check_modules(libmesh REQUIRED IMPORTED_TARGET libmesh)

# workaround for bogus libmesh include path
get_target_property(
  LIBMESH_INCLUDE_DIRECTORIES PkgConfig::libmesh INTERFACE_INCLUDE_DIRECTORIES)
list(REMOVE_ITEM LIBMESH_INCLUDE_DIRECTORIES "/usr/include/tirpc")
set_property(TARGET PkgConfig::libmesh
  PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${LIBMESH_INCLUDE_DIRECTORIES})

include(FeatureSummary)
feature_summary(WHAT ALL)

set(SRC_FILES "")
set(HDR_FILES "")

macro(libmesh_sandbox_add_exe)
  set(options EXCLUDE_FROM_ALL)
  set(oneValueArgs TARGET_NAME)
  set(multiValueArgs SOURCES HEADERS)
  cmake_parse_arguments(LIBMESH_SANDBOX_ADD_EXE
    "${options}"
    "${oneValueArgs}"
    "${multiValueArgs}"
    ${ARGN}
  )

  # message(STATUS "EXCLUDE_FROM_ALL = ${LIBMESH_SANDBOX_ADD_EXE_EXCLUDE_FROM_ALL}")
  # message(STATUS "TARGET_NAME = ${LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME}")
  # message(STATUS "SOURCES = ${LIBMESH_SANDBOX_ADD_EXE_SOURCES}")
  # message(STATUS "HEADERS = ${LIBMESH_SANDBOX_ADD_EXE_HEADERS}")

  if(NOT LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME)
    message(FATAL_ERROR "TARGET_NAME should always be specified")
  endif()

  if(NOT LIBMESH_SANDBOX_ADD_EXE_SOURCES)
    message(FATAL_ERROR "at least one file must be specified in SOURCES")
  endif()

  string(REPLACE "${CMAKE_SOURCE_DIR}/" "" SUBDIR ${CMAKE_CURRENT_SOURCE_DIR})

  message(STATUS "adding exe ${LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME} in ${SUBDIR}")
  add_executable(${LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME})
  target_sources(${LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME}
    PRIVATE ${LIBMESH_SANDBOX_ADD_EXE_SOURCES}
    PUBLIC ${LIBMESH_SANDBOX_ADD_EXE_HEADERS}
  )

  target_link_libraries(${LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME}
    PUBLIC
      MPI::MPI_CXX
      PkgConfig::libmesh
      fmt::fmt
      yaml-cpp
  )

  add_test(
    NAME ${LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME}
    COMMAND mpirun -np 2 ${LIBMESH_SANDBOX_ADD_EXE_TARGET_NAME}
  )

  foreach(SRC_FILE ${LIBMESH_SANDBOX_ADD_EXE_SOURCES} )
    list(APPEND SRC_FILES "${SUBDIR}/${SRC_FILE}")
  endforeach()
  set(SRC_FILES "${SRC_FILES}" PARENT_SCOPE)
  foreach(HDR_FILE ${LIBMESH_SANDBOX_ADD_EXE_HEADERS} )
    list(APPEND HDR_FILES "${SUBDIR}/${HDR_FILE}")
  endforeach()
  set(HDR_FILES "${HDR_FILES}" PARENT_SCOPE)

endmacro()

include(CTest)

add_subdirectory(advection1d)
add_subdirectory(advection2d)
add_subdirectory(dirichlet)
add_subdirectory(elem_add)
add_subdirectory(gmshread)
add_subdirectory(hermite1d)
add_subdirectory(neumann2d)
add_subdirectory(ns)
add_subdirectory(self_lumping1d)
add_subdirectory(soltransfer)
add_subdirectory(stokes2d)
add_subdirectory(stokes3d)
add_subdirectory(test1d)
add_subdirectory(test2d)

message(STATUS "SRC_FILES = ${SRC_FILES}")
message(STATUS "HDR_FILES = ${HDR_FILES}")

find_program(CLANGFORMAT clang-format)
if (CLANGFORMAT)
  add_custom_target(clang-format
    COMMAND ${CLANGFORMAT}
    --verbose -i
    ${SRC_FILES} ${HDR_FILES}
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  )
else()
  add_custom_target(clang-format
    COMMAND echo "clang-format could not be found"
  )
endif()