Initial

Author: dbakker

README.rst

@@ -0,0 +1,36 @@
+Vim Adjust Scroll
+=================
+
+This plugin attempts to automatically adjust your Vim viewport so that about
+1/3 of the text you're looking at is above and 2/3 of the text is below your
+cursor.
+
+This is achieved by scrolling automatically whenever:
+
+    * You open another file
+    * You jump a large distance in the current buffer
+
+Take a look at the source if you're curious to how it works!
+
+Installing
+----------
+
+For NeoBundle_ add the following to your `.vimrc`::
+
+    NeoBundle 'dbakker/vim-adjustscroll'
+
+For Pathogen_, execute::
+
+    cd ~/.vim/bundle
+    git clone https://github.com/dbakker/vim-holmes.git
+    vim +Helptags +q
+
+That's pretty much it!
+
+License
+=======
+
+Copyright (c) Daan Bakker. Distributed under the same terms as Vim itself. See `:help license`.
+
+.. _Pathogen: https://github.com/tpope/vim-pathogen
+.. _NeoBundle: https://github.com/Shougo/neobundle.vim

autoload/adjustscroll.vim

@@ -0,0 +1,43 @@
+if exists("autoloaded_adjustscroll") || &cp
+  finish
+endif
+let autoloaded_adjustscroll = '0.1'
+
+" adjustscroll#reset(): Choose a nice horizontal and vertical scroll position {{{2
+fun! adjustscroll#reset()
+  normal! zt
+  let scroll = (winheight(0)-&scrolloff*2-1)/3
+  if scroll>0
+    exe 'normal! '.scroll."\<C-Y>"
+  endif
+
+  " Show as much of the code as possible near the end of the document
+  if line('$') == line('w$')
+    normal! zb
+    while line('$') != line('w$')
+      exe "normal! \<C-E>"
+    endwhile
+  endif
+
+  " Scroll the text horizontally to position the cursor at the right side of the screen.
+  normal! ze
+endf
+
+" adjustscroll#check(command): Runs the specified command and updates viewport {{{2
+fun! adjustscroll#check(command)
+  if len(a:command) == 0
+    return adjustscroll#reset()
+  endif
+
+  let [buf, start, end] = [bufnr(''), line('w0'), line('w$')]
+  sil exe a:command
+  if bufnr('') != buf || (line('w0') > end || line('w$') < start)
+    call adjustscroll#reset()
+  endif
+endf
+
+fun! adjustscroll#remap_normal(command)
+  " Insert <C-u> et al literally into the map
+  let z = substitute(a:command, '\v\<.[\+-].\>', '<C-v>\0', 'g')
+  exe 'nnoremap <silent> '.a:command.' :<C-u>call adjustscroll#check("normal! ".(v:count>0?v:count : "")."'.z.'")<cr>'
+endf

plugin/adjustscroll.vim

@@ -0,0 +1,24 @@
+if exists("loaded_adjustscroll") || &cp
+  finish
+endif
+let loaded_adjustscroll = '0.1'
+
+com! -nargs=* AdjustScroll call adjustscroll#check(<q-args>)
+
+if !exists('g:adjustscroll_auto') || g:adjustscroll_auto == 1
+  aug AutoAdjustScroll
+    au!
+    au VimResized * AdjustScroll
+    au BufWinEnter * AdjustScroll
+  aug END
+endif
+
+if !exists('g:adjustscroll_remap') || g:adjustscroll_remap == 1
+  for i in split('`. gg G zr zm <C-O> <C-I> <C-W>o <C-U> <C-D> <C-6> * # n N <C-]> gd')
+    if len(maparg(i, 'n')) == 0
+      call adjustscroll#remap_normal(i)
+    endif
+  endfor
+  nnoremap <silent> <PageDown> <PageDown>:AdjustScroll<cr>
+  nnoremap <silent> <PageUp> <PageUp>:AdjustScroll<cr>
+endif