flashcardsinspace/build.gradle.kts at main · elimxim/flashcardsinspace · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
import com.github.gradle.node.npm.task.NpmTask

plugins {
    val kotlinVersion = "2.1.0"
    kotlin("jvm") version kotlinVersion
    kotlin("plugin.spring") version kotlinVersion
    kotlin("plugin.jpa") version kotlinVersion
    id("org.springframework.boot") version "3.5.4"
    id("io.spring.dependency-management") version "1.1.7"
    id("com.github.node-gradle.node") version "7.1.0"
    id("application")
}

kotlin {
    compilerOptions {
        jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_23)
        freeCompilerArgs.addAll("-Xjsr305=strict")
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_24
    targetCompatibility = JavaVersion.VERSION_23
    toolchain {
        languageVersion = JavaLanguageVersion.of(24)
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation(kotlin("stdlib"))
    implementation("org.springframework.boot:spring-boot-starter-data-jpa")
    implementation("org.springframework.boot:spring-boot-starter-security")
    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation("org.springframework.boot:spring-boot-starter-validation")
    implementation("org.springframework.boot:spring-boot-starter-oauth2-authorization-server")
    implementation("org.springframework.boot:spring-boot-starter-oauth2-resource-server")
    implementation("org.springframework.boot:spring-boot-starter-thymeleaf")
    implementation("org.springframework.boot:spring-boot-starter-actuator")
    implementation("org.springframework.boot:spring-boot-starter-cache")
    implementation("com.fasterxml.jackson.module:jackson-module-kotlin")
    implementation("org.jetbrains.kotlin:kotlin-reflect")
    implementation("io.jsonwebtoken:jjwt-api:0.11.5")
    implementation("io.jsonwebtoken:jjwt-impl:0.11.5")
    implementation("io.jsonwebtoken:jjwt-jackson:0.11.5")
    implementation("org.liquibase:liquibase-core")
    implementation("com.brevo:brevo:1.1.0")
    implementation("com.googlecode.owasp-java-html-sanitizer:owasp-java-html-sanitizer:20240325.1")
    implementation("io.hawt:hawtio-springboot:4.2.0")
    implementation("org.jolokia:jolokia-core:1.7.2")
    implementation("com.github.ben-manes.caffeine:caffeine:3.2.3")
    implementation("com.github.usefulness:webp-imageio:0.10.2")

    runtimeOnly("org.postgresql:postgresql")

    testImplementation(kotlin("test"))
    testImplementation("io.mockk:mockk:1.13.11")
    testImplementation("org.mockito.kotlin:mockito-kotlin:5.4.0")
    testImplementation("org.springframework.boot:spring-boot-starter-test")
    testImplementation("org.springframework.security:spring-security-test")

    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
}

application {
    mainClass.set("com.github.elimxim.flashcardsinspace.AppKt")
    applicationName = "flash"
    applicationDefaultJvmArgs = listOf(
        "-Xmx800m",
        "-Xms800m",
        "-XX:+UseSerialGC",
        "-XX:+ExitOnOutOfMemoryError",
        "-XX:+HeapDumpOnOutOfMemoryError",
        "-XX:HeapDumpPath=/tmp/flashcardsinspace.hprof",
    )
}

springBoot {
    mainClass.set("com.github.elimxim.flashcardsinspace.AppKt")
}

node {
    version = "26.8.1"
    npmVersion = "11.19.0"
    download = true
    nodeProjectDir = file("src/main/vue")
}

tasks.register<NpmTask>("npmRunBuild") {
    dependsOn("npmInstall")
    npmCommand.set(listOf("run", "build"))
    inputs.dir("src/main/vue")
    outputs.dir(project.layout.buildDirectory.dir("resources/main/static/").get().asFile.toString())
}

tasks.register<NpmTask>("npmRunTest") {
    dependsOn("npmInstall")
    npmCommand.set(listOf("run", "test", "--", "--run"))
    inputs.dir("src/main/vue/src")
}

tasks.register<NpmTask>("npmRunLint") {
    dependsOn("npmInstall")
    npmCommand.set(listOf("run", "lint"))
    inputs.dir("src/main/vue/src")
}

tasks.register<NpmTask>("npmRunTypeCheck") {
    dependsOn("npmInstall")
    npmCommand.set(listOf("run", "type-check"))
    inputs.dir("src/main/vue/src")
}

tasks.named("processResources") {
    dependsOn("npmRunBuild")
}

tasks.withType<Test> {
    dependsOn("npmRunTest")
    useJUnitPlatform()
}