unboxing/meson.build at main · elly-code/unboxing · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
project(
    'io.github.elly_code.unboxing',
    'vala', 'c',
    version: '1.0.3',
    meson_version: '>= 0.59'
)

gnome = import('gnome')
i18n = import('i18n')

add_global_arguments('-DGETTEXT_PACKAGE="@0@"'.format (meson.project_name()), language:'c')

vapi_dir = join_paths(meson.current_source_dir(), 'vapi')
add_project_arguments(['--vapidir', vapi_dir], language: 'vala')

config_data = configuration_data()
config_data.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
config_data.set_quoted('GETTEXT_PACKAGE', meson.project_name())
config_file = configure_file(
    input: 'src/Config.vala.in',
    output: '@BASENAME@',
    configuration: config_data
)

gresource = gnome.compile_resources(
    'gresource',
    'data' / 'unboxing.gresource.xml',
    source_dir: 'data'
)

executable(
    meson.project_name(),
    config_file,
    gresource,
    'src/Utils/EnumToLocText.vala',
    'src/Utils/FileOperations.vala',
    'src/Views/AbstractView.vala',
    'src/Views/ErrorView.vala',
    'src/Views/MainView.vala',
    'src/Views/ProgressView.vala',
    'src/Views/SuccessView.vala',
    'src/Application.vala',
    'src/MainWindow.vala',
    'src/Welcome.vala',
    'src/Backend.vala',
    dependencies: [
        dependency('packagekit-glib2'),
        dependency ('glib-2.0'),
        dependency ('gobject-2.0'),
        dependency ('granite-7'),
        dependency ('gtk4')
    ],
    install : true
)

subdir('data')
subdir('po')

gnome.post_install(
    glib_compile_schemas: true,
    update_desktop_database: true
)