-
Notifications
You must be signed in to change notification settings - Fork 18
/
Copy pathtest-init-loader.el
215 lines (175 loc) · 7.22 KB
/
test-init-loader.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
;;; test-init-loader.el --- Test for init-loader.el
;; Copyright (C) 2013 by emacs-jp
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;;; Code:
(require 'cl-lib)
(require 'ert)
(require 'init-loader)
(defvar init-loader-test-files
'("00_utils.el"
"23_yaml.el"
"01_ik-cmd.el"
"96_color.el"
"20_elisp.el"
"21_javascript.el"
"25_perl.el"
"98_emacs-config.el"
"99_global-keys.el"
"carbon-emacs-config.el"
"carbon-emacs-migemo.el"
"nw-config.el"
"emacs-migemo.el"
"windows-powershell.el"
"windows-fonts.el"
"meadow-cmd.el"
"meadow-config.el"
"meadow-gnuserv.el"
"meadow-shell.el"
"meadow-w32-symlinks.el"
"linux-fonts.el"
"linux-commands.el"
"bsd-config.el"
"bsd-migemo.el"))
(ert-deftest init-loader--re-load-files ()
"Test for `init-loader--re-load-files'"
(cl-letf (((symbol-function #'directory-files)
(lambda (dir &optional full match nosort)
init-loader-test-files)))
(let ((got (init-loader--re-load-files init-loader-default-regexp "" t))
(expected '("00_utils.el" "01_ik-cmd.el" "20_elisp.el"
"21_javascript.el" "23_yaml.el" "25_perl.el"
"96_color.el" "98_emacs-config.el" "99_global-keys.el")))
(should (equal got expected)))
(let ((got (init-loader--re-load-files init-loader-windows-regexp "" t))
(expected '("windows-fonts.el" "windows-powershell.el")))
(should (equal got expected)))
(let ((got (init-loader--re-load-files init-loader-meadow-regexp "" t))
(expected '("meadow-cmd.el" "meadow-config.el" "meadow-gnuserv.el"
"meadow-shell.el" "meadow-w32-symlinks.el")))
(should (equal got expected)))
(let ((got (init-loader--re-load-files init-loader-carbon-emacs-regexp "" t))
(expected '("carbon-emacs-config.el" "carbon-emacs-migemo.el")))
(should (equal got expected)))
(let ((got (init-loader--re-load-files init-loader-linux-regexp "" t))
(expected '("linux-commands.el" "linux-fonts.el")))
(should (equal got expected)))
(let ((got (init-loader--re-load-files init-loader-bsd-regexp "" t))
(expected '("bsd-config.el" "bsd-migemo.el")))
(should (equal got expected)))
(let ((got (init-loader--re-load-files init-loader-nw-regexp "" t))
(expected '("nw-config.el")))
(should (equal got expected)))
;; accept '.elc' files
(push "nw-added.elc" init-loader-test-files)
(let ((got (init-loader--re-load-files init-loader-nw-regexp "" t))
(expected '("nw-added.elc" "nw-config.el")))
(should (equal got expected)))
(pop init-loader-test-files)))
(ert-deftest init-loader-follow-symlink ()
"Test for `init-loader-follow-symlink'"
(cl-letf (((symbol-function #'directory-files)
(lambda (dir &optional full match nosort)
init-loader-test-files)))
(let ((symlink "symlink.el")
(thisfile "test-init-loader.el"))
;; setup
(make-symbolic-link thisfile symlink t)
;; symbolic link
(let ((expected (expand-file-name (concat default-directory thisfile))))
(should (string= (init-loader-follow-symlink symlink) expected)))
;; not symbolic link
(let ((expected (getenv "HOME")))
(should (string= (init-loader-follow-symlink "~") expected)))
;; teardown
(delete-file symlink))))
(ert-deftest init-loader-load ()
"Test `init-loader-load'"
;; Test `init-loader-show-log-after-init' switch.
(cl-letf (((symbol-function #'directory-files)
(lambda (dir &optional full match nosort)
init-loader-test-files)))
(let ((init-loader-show-log-after-init t)
(after-init-hook nil))
(init-loader-load "")
(should
(and (member 'init-loader-show-log after-init-hook)
(not (member 'init-loader--show-log-error-only after-init-hook)))))
(let ((init-loader-show-log-after-init 'error-only)
(after-init-hook nil))
(init-loader-load "")
(should
(and (not (member 'init-loader-show-log after-init-hook))
(member 'init-loader--show-log-error-only after-init-hook))))
(let ((init-loader-show-log-after-init nil)
(after-init-hook nil))
(init-loader-load "")
(should
(and (not (member 'init-loader-show-log after-init-hook))
(not (member 'init-loader--show-log-error-only after-init-hook)))))))
(ert-deftest init-loader-log ()
"Test for `init-loader-log'"
;; pass not string value
(should-not (init-loader-log 1))
;; log message
(init-loader-log "message1")
(should (string= "message1" (init-loader-log)))
;; log message again
(init-loader-log "message2")
(should (string= "message1\nmessage2" (init-loader-log))))
(ert-deftest init-loader-error-log ()
"Test for `init-loader-error-log'"
;; pass not string value
(should-not (init-loader-error-log 1))
;; log message
(init-loader-error-log "message1")
(should (string= "message1" (init-loader-error-log)))
;; log message again
(init-loader-error-log "message2")
(should (string= "message1\nmessage2" (init-loader-error-log))))
(defvar is-byte-compiled nil)
(defvar is-loaded nil)
(defvar is-deleted nil)
(defun test-init-loader-clear-flags ()
(setq is-byte-compiled nil is-loaded nil is-deleted nil))
(ert-deftest init-loader-load-file ()
"Test for `init-loader-load-file'"
(cl-letf (((symbol-function #'byte-compile-file)
(lambda (el)
(setq is-byte-compiled t)))
((symbol-function #'load)
(lambda (file &optional noerror nomessage nosuffix must-suffix)
(setq is-loaded t)))
((symbol-function #'delete-file)
(lambda (file &optional trash)
(setq is-deleted t)))
((symbol-function #'locate-library)
(lambda (lib &optional nosuffix path interactive-call)
lib)))
;; not byte compile
(let ((init-loader-byte-compile nil))
(init-loader-load-file "foo")
(should (and (not is-byte-compiled) is-loaded)))
(test-init-loader-clear-flags)
(let ((init-loader-byte-compile t))
(init-loader-load-file "foo")
(should (and is-byte-compiled (not is-deleted)
is-loaded)))
(test-init-loader-clear-flags)
(let ((init-loader-byte-compile t))
;; .elc file is older than .el file
(shell-command "touch foo.elc ; sleep 1")
(shell-command "touch foo.el")
(init-loader-load-file "foo")
(should (and is-byte-compiled is-deleted is-loaded))
(shell-command "rm -f foo.el foo.elc"))))
;;; test-init-loader.el end here