kptncook/justfile at main · ephes/kptncook · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
# Justfile for kptncook project development

# Default recipe - show available commands
default:
    @just --list

# Install Python dependencies via uv
install:
    uv sync

# Update prek hook revisions
update-hooks:
    env -u VIRTUAL_ENV uv run prek auto-update

# Run lint, typecheck, and tests
check:
    just lint
    just typecheck
    just test

# Run the full test suite
test:
    uv run pytest

# Run a specific test (pass path or node id)
test-one TARGET:
    uv run pytest {{TARGET}} -v

# Run type checks with mypy
typecheck:
    uv run mypy src

# Lint and format with Ruff
lint:
    uv run ruff format .
    uv run ruff check .

# Count lines in the repository with language, area, and directory summaries
loc:
    @uv run --with-editable ../slopscope slopscope .

# Prepare a release by moving Unreleased notes into a dated section and bumping the package version
release-prepare VERSION:
    uv run python -m kptncook.release prepare {{VERSION}}

# Print changelog notes for a specific release version
release-notes VERSION:
    uv run python -m kptncook.release notes {{VERSION}}

# Create a draft GitHub release from the changelog notes for a specific version
release-draft VERSION:
    uv run python -m kptncook.release draft {{VERSION}}

# Remove build artifacts
clean-build:
    rm -fr build/
    rm -fr dist/
    rm -fr *.egg-info

# Remove Python file artifacts
clean-pyc:
    find . \( -path "./.venv" -o -path "./.beads" -o -path "./.git" \) -prune -o -name '*.pyc' -exec rm -f {} +
    find . \( -path "./.venv" -o -path "./.beads" -o -path "./.git" \) -prune -o -name '*.pyo' -exec rm -f {} +
    find . \( -path "./.venv" -o -path "./.beads" -o -path "./.git" \) -prune -o -name '*~' -exec rm -f {} +

# Remove all build and Python artifacts
clean: clean-build clean-pyc

# Beadsflow autopilot helpers (local checkout)
beadsflow-dry EPIC:
    uv run --project ../beadsflow beadsflow run {{EPIC}} --dry-run --verbose

beadsflow-once EPIC:
    uv run --project ../beadsflow beadsflow run {{EPIC}} --once --verbose

beadsflow-run EPIC:
    uv run --project ../beadsflow beadsflow run {{EPIC}} --interval 30 --verbose

# Import GitHub issues into Beads epics
beads-import-gh-issues *ARGS:
    uv run python scripts/import_github_issues_to_beads.py {{ARGS}}