skipper-java/build.gradle.kts at main · get-skipper/skipper-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
val skipperVersion = project.findProperty("version")?.toString()
    ?.takeIf { it != "unspecified" }
    ?: "1.2.0"

subprojects {
    apply(plugin = "java-library")

    repositories {
        mavenCentral()
    }
    apply(plugin = "maven-publish")

    group = "io.getskipper"
    version = skipperVersion

    extensions.configure<JavaPluginExtension> {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
        withSourcesJar()
        withJavadocJar()
    }

    tasks.withType<Test> {
        useJUnitPlatform()
        testLogging {
            events("passed", "failed", "skipped")
        }
        // Run tests from the project root so that service-account-skipper-bot.json
        // is resolved correctly relative to the workspace root.
        workingDir = rootProject.projectDir
    }

    extensions.configure<PublishingExtension> {
        publications {
            create<MavenPublication>("maven") {
                from(components["java"])
                groupId = "io.getskipper"
                pom {
                    url.set("https://github.com/get-skipper/skipper-java")
                    licenses {
                        license {
                            name.set("MIT License")
                            url.set("https://opensource.org/licenses/MIT")
                        }
                    }
                    scm {
                        connection.set("scm:git:git://github.com/get-skipper/skipper-java.git")
                        url.set("https://github.com/get-skipper/skipper-java")
                    }
                }
            }
        }
        repositories {
            maven {
                name = "GitHubPackages"
                url = uri("https://maven.pkg.github.com/get-skipper/skipper-java")
                credentials {
                    username = System.getenv("GITHUB_ACTOR") ?: ""
                    password = System.getenv("GITHUB_TOKEN") ?: ""
                }
            }
        }
    }
}