|
| 1 | +{-# LANGUAGE NamedFieldPuns #-} |
| 2 | + |
| 3 | +module Distribution.Client.CmdGenBounds |
| 4 | + ( genBounds |
| 5 | + , genBoundsCommand |
| 6 | + , genBoundsAction |
| 7 | + , GenBoundsFlags (..) |
| 8 | + , defaultGenBoundsFlags |
| 9 | + ) where |
| 10 | + |
| 11 | +import Distribution.Client.Compat.Prelude |
| 12 | +import Prelude () |
| 13 | + |
| 14 | +import qualified Data.Map as Map |
| 15 | + |
| 16 | +import Distribution.Client.Errors |
| 17 | + |
| 18 | +import Distribution.Client.ProjectPlanning hiding (pruneInstallPlanToTargets) |
| 19 | +import Distribution.Client.ProjectPlanning.Types |
| 20 | +import Distribution.Client.Types.ConfiguredId (confInstId) |
| 21 | +import Distribution.Client.Utils hiding (pvpize) |
| 22 | +import Distribution.InstalledPackageInfo (InstalledPackageInfo, installedComponentId) |
| 23 | +import Distribution.Package |
| 24 | +import Distribution.PackageDescription |
| 25 | +import Distribution.Simple.Utils |
| 26 | +import Distribution.Version |
| 27 | + |
| 28 | +import Distribution.Client.Setup (CommonSetupFlags (..), ConfigFlags (..), GlobalFlags (..)) |
| 29 | + |
| 30 | +-- Project orchestration imports |
| 31 | + |
| 32 | +import Distribution.Client.CmdErrorMessages |
| 33 | +import Distribution.Client.GenBounds |
| 34 | +import qualified Distribution.Client.InstallPlan as InstallPlan |
| 35 | +import Distribution.Client.NixStyleOptions |
| 36 | +import Distribution.Client.ProjectFlags |
| 37 | +import Distribution.Client.ProjectOrchestration |
| 38 | +import Distribution.Client.ScriptUtils |
| 39 | +import Distribution.Client.TargetProblem |
| 40 | +import Distribution.Simple.Command |
| 41 | +import Distribution.Simple.Flag |
| 42 | +import Distribution.Types.Component |
| 43 | +import Distribution.Verbosity |
| 44 | + |
| 45 | +-- | The data type for gen-bounds command flags |
| 46 | +data GenBoundsFlags = GenBoundsFlags {} |
| 47 | + |
| 48 | +-- | Default values for the gen-bounds flags |
| 49 | +defaultGenBoundsFlags :: GenBoundsFlags |
| 50 | +defaultGenBoundsFlags = GenBoundsFlags{} |
| 51 | + |
| 52 | +-- | The @gen-bounds@ command definition |
| 53 | +genBoundsCommand :: CommandUI (NixStyleFlags GenBoundsFlags) |
| 54 | +genBoundsCommand = |
| 55 | + CommandUI |
| 56 | + { commandName = "v2-gen-bounds" |
| 57 | + , commandSynopsis = "Generate dependency bounds for packages in the project." |
| 58 | + , commandUsage = usageAlternatives "v2-gen-bounds" ["[TARGETS] [FLAGS]"] |
| 59 | + , commandDescription = Just $ \_ -> |
| 60 | + "Generate PVP-compliant dependency bounds for packages in the project." |
| 61 | + , commandNotes = Just $ \pname -> |
| 62 | + "Examples:\n" |
| 63 | + ++ " " |
| 64 | + ++ pname |
| 65 | + ++ " v2-gen-bounds\n" |
| 66 | + ++ " Generate bounds for the package in the current directory " |
| 67 | + ++ "or all packages in the project\n" |
| 68 | + ++ " " |
| 69 | + ++ pname |
| 70 | + ++ " v2-gen-bounds pkgname\n" |
| 71 | + ++ " Generate bounds for the package named pkgname in the project\n" |
| 72 | + ++ " " |
| 73 | + ++ pname |
| 74 | + ++ " v2-gen-bounds ./pkgfoo\n" |
| 75 | + ++ " Generate bounds for the package in the ./pkgfoo directory\n" |
| 76 | + , commandDefaultFlags = defaultNixStyleFlags defaultGenBoundsFlags |
| 77 | + , commandOptions = |
| 78 | + removeIgnoreProjectOption |
| 79 | + . nixStyleOptions (const []) |
| 80 | + } |
| 81 | + |
| 82 | +-- | The action for the @gen-bounds@ command when used in a project context. |
| 83 | +genBoundsAction :: NixStyleFlags GenBoundsFlags -> [String] -> GlobalFlags -> IO () |
| 84 | +genBoundsAction flags targetStrings globalFlags = |
| 85 | + withContextAndSelectors RejectNoTargets Nothing flags targetStrings globalFlags OtherCommand $ \targetCtx ctx targetSelectors -> do |
| 86 | + let verbosity = fromFlagOrDefault normal (setupVerbosity $ configCommonFlags $ configFlags flags) |
| 87 | + |
| 88 | + baseCtx <- case targetCtx of |
| 89 | + ProjectContext -> return ctx |
| 90 | + GlobalContext -> return ctx |
| 91 | + ScriptContext path _ -> |
| 92 | + dieWithException verbosity $ |
| 93 | + GenBoundsDoesNotSupportScript path |
| 94 | + |
| 95 | + let ProjectBaseContext{distDirLayout, cabalDirLayout, projectConfig, localPackages} = baseCtx |
| 96 | + |
| 97 | + -- Step 1: Create the install plan for the project. |
| 98 | + (_, elaboratedPlan, _, _, _) <- |
| 99 | + rebuildInstallPlan |
| 100 | + verbosity |
| 101 | + distDirLayout |
| 102 | + cabalDirLayout |
| 103 | + projectConfig |
| 104 | + localPackages |
| 105 | + Nothing |
| 106 | + |
| 107 | + -- Step 2: Resolve the targets for the gen-bounds command. |
| 108 | + targets <- |
| 109 | + either (reportGenBoundsTargetProblems verbosity) return $ |
| 110 | + resolveTargets |
| 111 | + selectPackageTargets |
| 112 | + selectComponentTarget |
| 113 | + elaboratedPlan |
| 114 | + Nothing |
| 115 | + targetSelectors |
| 116 | + |
| 117 | + -- Step 3: Prune the install plan to the targets. |
| 118 | + let elaboratedPlan' = |
| 119 | + pruneInstallPlanToTargets |
| 120 | + TargetActionBuild |
| 121 | + targets |
| 122 | + elaboratedPlan |
| 123 | + |
| 124 | + let |
| 125 | + -- Step 4a: Find the local packages from the install plan. These are the |
| 126 | + -- candidates for which we will generate bounds. |
| 127 | + localPkgs :: [ElaboratedConfiguredPackage] |
| 128 | + localPkgs = mapMaybe (InstallPlan.foldPlanPackage (const Nothing) (\p -> Just p)) (InstallPlan.toList elaboratedPlan') |
| 129 | + |
| 130 | + -- Step 4b: Extract which versions we chose for each package from the pruned install plan. |
| 131 | + pkgVersionMap :: Map.Map ComponentId PackageIdentifier |
| 132 | + pkgVersionMap = Map.fromList (map (InstallPlan.foldPlanPackage externalVersion localVersion) (InstallPlan.toList elaboratedPlan')) |
| 133 | + |
| 134 | + externalVersion :: InstalledPackageInfo -> (ComponentId, PackageIdentifier) |
| 135 | + externalVersion pkg = (installedComponentId pkg, packageId pkg) |
| 136 | + |
| 137 | + localVersion :: ElaboratedConfiguredPackage -> (ComponentId, PackageIdentifier) |
| 138 | + localVersion pkg = (elabComponentId pkg, packageId pkg) |
| 139 | + |
| 140 | + let genBoundsActionForPkg :: ElaboratedConfiguredPackage -> [IO ()] |
| 141 | + genBoundsActionForPkg pkg = |
| 142 | + -- Step 5: Match up the user specified targets with the local packages. |
| 143 | + case Map.lookup (installedUnitId pkg) targets of |
| 144 | + Nothing -> [] |
| 145 | + Just tgts -> |
| 146 | + map (\(tgt, _) -> processBuildInfo verbosity tgt pkg pkgVersionMap) tgts |
| 147 | + |
| 148 | + -- Process each package to find the ones needing bounds |
| 149 | + let boundsActions = concatMap genBoundsActionForPkg localPkgs |
| 150 | + |
| 151 | + case boundsActions of |
| 152 | + [] -> notice verbosity "All bounds up-to-date" |
| 153 | + _ -> do |
| 154 | + notice verbosity boundsNeededMsg |
| 155 | + sequence_ (intersperse (putStrLn "") boundsActions) |
| 156 | + |
| 157 | +-- | Process a single BuildInfo to identify and report missing upper bounds |
| 158 | +processBuildInfo |
| 159 | + :: Verbosity |
| 160 | + -> ComponentTarget |
| 161 | + -> ElaboratedConfiguredPackage |
| 162 | + -> Map.Map ComponentId PackageIdentifier |
| 163 | + -> IO () |
| 164 | +processBuildInfo verbosity tgt pkg pkgVersionMap = do |
| 165 | + let pd = elabPkgDescription pkg |
| 166 | + -- Extract the build-depends for the right part of the cabal file. |
| 167 | + bi = buildInfoForTarget pd tgt |
| 168 | + |
| 169 | + -- We need to generate bounds if |
| 170 | + -- \* the dependency does not have an upper bound |
| 171 | + -- \* the dependency is not the same package as the one we are processing |
| 172 | + boundFilter dep = |
| 173 | + (not (hasUpperBound (depVerRange dep))) |
| 174 | + && packageName pd /= depPkgName dep |
| 175 | + |
| 176 | + -- The dependencies that need bounds. |
| 177 | + needBounds = map depPkgName $ filter boundFilter $ targetBuildDepends bi |
| 178 | + |
| 179 | + if null needBounds |
| 180 | + then |
| 181 | + notice |
| 182 | + verbosity |
| 183 | + ("Congratulations, all dependencies for " ++ prettyShow (packageName pd) ++ ":" ++ showComponentTarget (packageId pkg) tgt ++ " have upper bounds!") |
| 184 | + else do |
| 185 | + notice verbosity $ |
| 186 | + "For component " ++ prettyShow (packageName pd) ++ ":" ++ showComponentTarget (packageId pkg) tgt ++ ":" |
| 187 | + |
| 188 | + -- All the things we depend on. |
| 189 | + let componentDeps = elabLibDependencies pkg |
| 190 | + -- Match these up to package names, this is a list of Package name to versions. |
| 191 | + -- Now just match that up with what the user wrote in the build-depends section. |
| 192 | + depsWithVersions = mapMaybe (\cid -> Map.lookup (confInstId $ fst cid) pkgVersionMap) componentDeps |
| 193 | + isNeeded = hasElem needBounds . packageName |
| 194 | + thePkgs = filter isNeeded depsWithVersions |
| 195 | + |
| 196 | + let padTo = maximum $ map (length . unPackageName . packageName) thePkgs |
| 197 | + |
| 198 | + traverse_ (notice verbosity . (++ ",") . showBounds padTo) thePkgs |
| 199 | + |
| 200 | +buildInfoForTarget :: PackageDescription -> ComponentTarget -> BuildInfo |
| 201 | +buildInfoForTarget pd (ComponentTarget cname _) = componentBuildInfo $ getComponent pd cname |
| 202 | + |
| 203 | +-- | This defines what a 'TargetSelector' means for the @gen-bounds@ command. |
| 204 | +-- Copy of selectPackageTargets from CmdBuild.hs |
| 205 | +selectPackageTargets |
| 206 | + :: TargetSelector |
| 207 | + -> [AvailableTarget k] |
| 208 | + -> Either TargetProblem' [k] |
| 209 | +selectPackageTargets targetSelector targets |
| 210 | + -- If there are any buildable targets then we select those |
| 211 | + | not (null targetsBuildable) = |
| 212 | + Right targetsBuildable |
| 213 | + -- If there are targets but none are buildable then we report those |
| 214 | + | not (null targets) = |
| 215 | + Left (TargetProblemNoneEnabled targetSelector targets') |
| 216 | + -- If there are no targets at all then we report that |
| 217 | + | otherwise = |
| 218 | + Left (TargetProblemNoTargets targetSelector) |
| 219 | + where |
| 220 | + targets' = forgetTargetsDetail targets |
| 221 | + targetsBuildable = |
| 222 | + selectBuildableTargetsWith |
| 223 | + (buildable targetSelector) |
| 224 | + targets |
| 225 | + |
| 226 | + -- When there's a target filter like "pkg:tests" then we do select tests, |
| 227 | + -- but if it's just a target like "pkg" then we don't build tests unless |
| 228 | + -- they are requested by default (i.e. by using --enable-tests) |
| 229 | + buildable (TargetPackage _ _ Nothing) TargetNotRequestedByDefault = False |
| 230 | + buildable (TargetAllPackages Nothing) TargetNotRequestedByDefault = False |
| 231 | + buildable _ _ = True |
| 232 | + |
| 233 | +-- | For a 'TargetComponent' 'TargetSelector', check if the component can be |
| 234 | +-- selected. Copy of selectComponentTarget from CmdBuild.hs |
| 235 | +selectComponentTarget |
| 236 | + :: SubComponentTarget |
| 237 | + -> AvailableTarget k |
| 238 | + -> Either TargetProblem' k |
| 239 | +selectComponentTarget = selectComponentTargetBasic |
| 240 | + |
| 241 | +-- | Report target problems for gen-bounds command |
| 242 | +reportGenBoundsTargetProblems :: Verbosity -> [TargetProblem'] -> IO a |
| 243 | +reportGenBoundsTargetProblems verbosity problems = |
| 244 | + reportTargetProblems verbosity "gen-bounds" problems |
0 commit comments