cmake: Build libbitcoinconsensus library

Author: hebasto

CMakeLists.txt

@@ -40,6 +40,13 @@ option(BUILD_DAEMON "Build bitcoind executable." ON)
 option(BUILD_CLI "Build bitcoin-cli executable." ON)
 option(BUILD_TX "Build bitcoin-tx executable." ON)
 option(BUILD_UTIL "Build bitcoin-util executable." ON)
+# We do not use CMake's BUILD_SHARED_LIBS option.
+option(BUILD_SHARED "Build shared libraries." ON)
+option(BUILD_STATIC "Build static libraries." ON)
+if(NOT BUILD_SHARED AND NOT BUILD_STATIC)
+  message(FATAL_ERROR "At least one of BUILD_SHARED and BUILD_STATIC must be enabled.")
+endif()
+option(BUILD_BITCOINCONSENSUS_LIB "Build bitcoinconsensus library." ON)
 option(ASM "Use assembly routines." ON)
 
 option(ENABLE_WALLET "Enable wallet." ON)
@@ -312,6 +319,10 @@ if(WERROR)
   endif()
 endif()
 
+if(BUILD_BITCOINCONSENSUS_LIB)
+  set(HAVE_CONSENSUS_LIB ON)
+endif()
+
 find_package(Python3 3.8 COMPONENTS Interpreter)
 set(PYTHON_COMMAND ${Python3_EXECUTABLE})
 
@@ -332,6 +343,10 @@ message("  bitcoin-cli ......................... ${BUILD_CLI}")
 message("  bitcoin-tx .......................... ${BUILD_TX}")
 message("  bitcoin-util ........................ ${BUILD_UTIL}")
 message("  bitcoin-wallet ...................... ${BUILD_WALLET_TOOL}")
+message("Libraries:")
+message("  build shared ........................ ${BUILD_SHARED}")
+message("  build static ........................ ${BUILD_STATIC}")
+message("  libbitcoinconsensus ................. ${BUILD_BITCOINCONSENSUS_LIB}")
 message("Wallet support:")
 message("  SQLite, descriptor wallets .......... ${WITH_SQLITE}")
 message("  Berkeley DB, legacy wallets ......... ${WITH_BDB}")

cmake/bitcoin-config.h.in

@@ -46,6 +46,9 @@
 /* Define to 1 if you have the <byteswap.h> header file. */
 #cmakedefine HAVE_BYTESWAP_H 1
 
+/* Define this symbol if the consensus lib has been built */
+#cmakedefine HAVE_CONSENSUS_LIB 1
+
 /* Define to 1 if you have the declaration of `be16toh', and to 0 if you
    don't. */
 #cmakedefine01 HAVE_DECL_BE16TOH

src/CMakeLists.txt

@@ -294,6 +294,11 @@ if(BUILD_UTIL)
 endif()
 
 
+if(BUILD_BITCOINCONSENSUS_LIB)
+  add_subdirectory(script)
+endif()
+
+
 add_subdirectory(test/util)
 if(BUILD_BENCH)
   add_subdirectory(bench)

src/bench/CMakeLists.txt

@@ -48,6 +48,11 @@ add_executable(bench_bitcoin
   xor.cpp
 )
 
+if(TARGET bitcoinconsensus_static)
+  target_link_libraries(bench_bitcoin bitcoinconsensus_static)
+elseif(TARGET bitcoinconsensus AND NOT WIN32)
+  target_link_libraries(bench_bitcoin bitcoinconsensus)
+endif()
 target_link_libraries(bench_bitcoin
   core
   test_util

src/script/CMakeLists.txt

@@ -0,0 +1,90 @@
+# Copyright (c) 2023-present The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or https://opensource.org/license/mit/.
+
+# Must be included before CMAKE_INSTALL_INCLUDEDIR is used.
+include(GNUInstallDirs)
+
+set(bitcoinconsensus_src
+  $<TARGET_OBJECTS:bitcoin_crypto>
+  interpreter.cpp
+  script.cpp
+  script_error.cpp
+  ../arith_uint256.cpp
+  ../consensus/merkle.cpp
+  ../consensus/tx_check.cpp
+  ../hash.cpp
+  ../primitives/block.cpp
+  ../primitives/transaction.cpp
+  ../pubkey.cpp
+  ../uint256.cpp
+  ../util/strencodings.cpp
+)
+
+if(BUILD_SHARED)
+  add_library(bitcoinconsensus SHARED "")
+  target_sources(bitcoinconsensus
+    PRIVATE
+      bitcoinconsensus.cpp
+      ../support/cleanse.cpp
+      ${bitcoinconsensus_src}
+  )
+  target_compile_definitions(bitcoinconsensus
+    PRIVATE
+      BUILD_BITCOIN_INTERNAL
+  )
+  target_include_directories(bitcoinconsensus
+    PUBLIC
+      $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src>
+      $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+  )
+  target_link_libraries(bitcoinconsensus
+    PRIVATE
+      core
+      secp256k1
+  )
+  set_target_properties(bitcoinconsensus PROPERTIES
+    SOVERSION 0
+    VERSION 0.0.0
+  )
+endif()
+
+if(BUILD_STATIC)
+  add_library(bitcoinconsensus_static STATIC "")
+  target_sources(bitcoinconsensus_static
+    PRIVATE
+      bitcoinconsensus.cpp
+      ../support/cleanse.cpp
+      ${bitcoinconsensus_src}
+  )
+  target_compile_definitions(bitcoinconsensus_static
+    PRIVATE
+      BUILD_BITCOIN_INTERNAL
+  )
+  target_include_directories(bitcoinconsensus_static
+    PUBLIC
+      $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src>
+      $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+  )
+  target_link_libraries(bitcoinconsensus_static
+    PRIVATE
+      core
+      secp256k1
+  )
+  if(NOT MSVC)
+    set_target_properties(bitcoinconsensus_static PROPERTIES
+      OUTPUT_NAME bitcoinconsensus
+    )
+  endif()
+endif()
+
+install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/bitcoinconsensus.h"
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+)
+
+set(prefix ${CMAKE_INSTALL_PREFIX})
+set(exec_prefix "\${prefix}")
+set(libdir "\${exec_prefix}/lib")
+set(includedir "\${prefix}/include")
+configure_file(${CMAKE_SOURCE_DIR}/libbitcoinconsensus.pc.in libbitcoinconsensus.pc @ONLY)
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libbitcoinconsensus.pc DESTINATION lib/pkgconfig)

src/test/CMakeLists.txt

@@ -134,6 +134,11 @@ add_executable(test_bitcoin
   xoroshiro128plusplus_tests.cpp
 )
 
+if(TARGET bitcoinconsensus_static)
+  target_link_libraries(test_bitcoin bitcoinconsensus_static)
+elseif(TARGET bitcoinconsensus AND NOT WIN32)
+  target_link_libraries(test_bitcoin bitcoinconsensus)
+endif()
 target_link_libraries(test_bitcoin
   core
   test_util