Emit a bitcast after select in SimplifyConstant

In typed pointer mode, LLVM inserts pointer bitcasts between GEPs and
loads of different types. This is not the case in opaque pointer mode
and causes an issue in SimplifyConstant when the GEP + load are replaced
with select of values. This change makes the pass emit a bitcast for
bitwise compatible types.

Author: michalpaszkowski

IGC/Compiler/CISACodeGen/SimplifyConstant.cpp

@@ -1,6 +1,6 @@
 /*========================== begin_copyright_notice ============================
 
-Copyright (C) 2017-2021 Intel Corporation
+Copyright (C) 2017-2025 Intel Corporation
 
 SPDX-License-Identifier: MIT
 
@@ -190,6 +190,12 @@ void ConstantLoader::simplify() {
                 Value* Cmp = Builder.CreateTrunc(Index, Builder.getInt1Ty());
                 Val = Builder.CreateSelect(Cmp, V1, V0);
             }
+
+            Type* SrcTy = Val->getType();
+            Type* DstTy = LI->getType();
+            if (SrcTy != DstTy && SrcTy->getPrimitiveSizeInBits() == DstTy->getPrimitiveSizeInBits())
+              Val = Builder.CreateBitCast(Val, DstTy);
+
             LI->replaceAllUsesWith(Val);
             LI->eraseFromParent();
         }

IGC/Compiler/tests/SimplifyConstant/basic-typed-pointers.ll

@@ -0,0 +1,36 @@
+;=========================== begin_copyright_notice ============================
+;
+; Copyright (C) 2022 Intel Corporation
+;
+; SPDX-License-Identifier: MIT
+;
+;============================ end_copyright_notice =============================
+;
+; RUN: igc_opt --typed-pointers -enable-debugify -SimplifyConstant -S < %s 2>&1 | FileCheck %s
+; ------------------------------------------------
+; SimplifyConstant
+; ------------------------------------------------
+
+; Debug-info related check
+;
+; CHECK-COUNT-1: WARNING
+; CHECK-SAME: Missing line 1
+; CHECK-NOT: WARNING
+; CHECK: CheckModuleDebugify: PASS
+
+@a = private addrspace(2) constant [4 x i32] [i32 13, i32 42, i32 13, i32 42], align 1
+
+define spir_kernel void @test_simpleconst(i32 %a, i32* %b) {
+; CHECK-LABEL: @test_simpleconst(
+; CHECK:  entry:
+; CHECK:    [[TMP0:%.*]] = trunc i32 [[A:%.*]] to i1
+; CHECK:    [[TMP1:%.*]] = select i1 [[TMP0]], i32 42, i32 13
+; CHECK:    store i32 [[TMP1]], i32* [[B:%.*]], align 4
+; CHECK:    ret void
+;
+entry:
+  %0 = getelementptr inbounds [4 x i32], [4 x i32] addrspace(2)* @a, i32 0, i32 %a
+  %1 = load i32, i32 addrspace(2)* %0, align 4
+  store i32 %1, i32* %b, align 4
+  ret void
+}

IGC/Compiler/tests/SimplifyConstant/basic.ll

@@ -6,7 +6,8 @@
 ;
 ;============================ end_copyright_notice =============================
 ;
-; RUN: igc_opt --typed-pointers -enable-debugify -SimplifyConstant -S < %s 2>&1 | FileCheck %s
+; REQUIRES: llvm-14-plus
+; RUN: igc_opt --opaque-pointers -enable-debugify -SimplifyConstant -S < %s 2>&1 | FileCheck %s
 ; ------------------------------------------------
 ; SimplifyConstant
 ; ------------------------------------------------
@@ -25,7 +26,7 @@ define spir_kernel void @test_simpleconst(i32 %a, i32* %b) {
 ; CHECK:  entry:
 ; CHECK:    [[TMP0:%.*]] = trunc i32 [[A:%.*]] to i1
 ; CHECK:    [[TMP1:%.*]] = select i1 [[TMP0]], i32 42, i32 13
-; CHECK:    store i32 [[TMP1]], i32* [[B:%.*]], align 4
+; CHECK:    store i32 [[TMP1]], ptr [[B:%.*]], align 4
 ; CHECK:    ret void
 ;
 entry:

IGC/Compiler/tests/SimplifyConstant/bitcast-after-simplification.ll

@@ -0,0 +1,40 @@
+;=========================== begin_copyright_notice ============================
+;
+; Copyright (C) 2025 Intel Corporation
+;
+; SPDX-License-Identifier: MIT
+;
+;============================ end_copyright_notice =============================
+
+; REQUIRES: llvm-14-plus
+; RUN: igc_opt --opaque-pointers -SimplifyConstant -S < %s 2>&1 | FileCheck %s
+
+; This test checks that SimplifyConstant pass emits a bitcast following
+; simplification.
+;
+; Before the transition to opaque pointers, the pass accepted the following pattern:
+; @g = dso_local unnamed_addr addrspace(2) constant [2 x i32] [i32 1065353216, i32 -1082130432], align 4
+; %gep = getelementptr inbounds [2 x i32], [2 x i32] addrspace(2)* @g, i64 0, i64 %a
+; %bc = bitcast i32 addrspace(2)* %30 to float addrspace(2)*
+; %load = load float, float addrspace(2)* %bc, align 4
+;
+; In opaque pointer mode, the pattern changes to:
+; @g = dso_local unnamed_addr addrspace(2) constant [2 x i32] [i32 1065353216, i32 -1082130432], align 4
+; %gep = getelementptr inbounds [2 x i32], ptr addrspace(2) @g, i64 0, i64 %a
+; %load = load float, ptr addrspace(2) %gep, align 4
+;
+; After simplification, the load expects a different primitive type and given
+; that the types are bitwise compatible, the pass can emit a bitcast.
+
+; CHECK: [[SELECT:%.*]] = select i1 {{%.*}}, i32 -1082130432, i32 1065353216
+; CHECK: [[BC:%.*]] = bitcast i32 [[SELECT]] to float
+; CHECK: store float [[BC]], ptr {{%.*}}, align 4
+
+@g = dso_local unnamed_addr addrspace(2) constant [2 x i32] [i32 1065353216, i32 -1082130432], align 4
+
+define spir_kernel void @test_bitcast_after_simplification(i64 %a, ptr %b) {
+  %gep = getelementptr inbounds [2 x i32], ptr addrspace(2) @g, i64 0, i64 %a
+  %load = load float, ptr addrspace(2) %gep, align 4
+  store float %load, ptr %b, align 4
+  ret void
+}