build.gradle

plugins {
    id 'java'
    id 'jacoco' //jacoco 추가
    id 'org.springframework.boot' version "${springBootVersion}" apply(false)
    id 'io.spring.dependency-management' version "${springDependencyManagementVersion}"
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(23)
    }
}

jacoco {
    toolVersion = '0.8.13'
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

allprojects {
    group = "${projectGroup}"
    version = "${applicationVersion}"

    repositories {
        mavenCentral()
    }
}

subprojects {
    apply {
        plugin 'java'
        plugin 'io.spring.dependency-management'
        plugin 'jacoco'
    }

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudDependenciesVersion}"
        }
    }

    sourceCompatibility = JavaVersion.VERSION_23
    targetCompatibility = JavaVersion.VERSION_23

    dependencies {
        // lombok
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        // test
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
        testImplementation 'io.rest-assured:rest-assured:5.4.0'
    }

    tasks.withType(Test).configureEach {
        useJUnitPlatform()
        finalizedBy 'jacocoTestReport'

        jacoco {
            includes = ['com.devoops.*']
            excludes = ['jdk.*', 'sun.*']
        }
    }

    tasks.named('jacocoTestReport', JacocoReport).configure {
        dependsOn test

        reports {
            xml.required.set(true)
            html.required.set(false)
            csv.required.set(false)
        }

        def excludedPatterns = ["com/devoops/**/dto/**"]

        // 기존 classDirectories의 FileCollection을 직접 다룬다
        def originalClassDirs = files(classDirectories)

        classDirectories.setFrom(
                originalClassDirs.collect {
                    fileTree(dir: it, exclude: excludedPatterns)
                }
        )

        onlyIf {
            // TEST_REPORT가 설정되지 않은 local 환경에선 돌아가지 않음
            // TEST_REPORT가 설정된 ci 스크립트 내에서만 jacoco report 실행
            System.getenv('TEST_REPORT') == 'true'
        }
    }
}

tasks.named('test') {
    useJUnitPlatform()
}