vertico-directory-tidy: consider always removing the overlay when typing /

[joca-bt]

When expanding ~/, vertico-directory-tidy removes the overlay after the user types /. However, when expanding //, the overlay is only removed after the next character is typed by the user, instead of when typing the second /.

Would it make sense to consistently remove the overlay when typing /?

[joca-bt]

This is how I did it

(defun vertico-directory-tidy ()
  "Tidy shadowed file name, see `rfn-eshadow-overlay'."
  (when (eq this-command #'self-insert-command)
    (dolist (ov '(tramp-rfn-eshadow-overlay rfn-eshadow-overlay))
      (when (and (boundp ov)
                 (setq ov (symbol-value ov))
                 (overlay-buffer ov)
                 (= (point) (point-max))
                 (> (point) (overlay-end ov))
                 (eq ?/ (char-before (point))))
        (delete-region (overlay-start ov) (overlay-end ov))))))

but I'm not sure of what the following may be guarding against (namely, why the 2)

(or (>= (- (point) (overlay-end ov)) 2)
    (eq ?/ (char-before (- (point) 2)))))

[minad]

I think the reason was that I wanted to reduce the aggressiveness of vertico-directory-tidy. The following is even more aggressive:

(defun vertico-directory-tidy ()
  "Tidy shadowed file name, see `rfn-eshadow-overlay'."
  (when (eq this-command #'self-insert-command)
    (dolist (ov '(tramp-rfn-eshadow-overlay rfn-eshadow-overlay))
      (when (and (boundp ov)
                 (setq ov (symbol-value ov))
                 (overlay-buffer ov)
                 (= (point) (point-max))
                 (> (point) (overlay-end ov)))
        (delete-region (overlay-start ov) (overlay-end ov))))))

As soon as you type ~, $HOME or /, the shadowed path will be removed immediately.

[minad]

We can try this for a while and see if users like it:

a6bd815