implement bootstrap() function

Author: azjezz

src/Nuxed/Environment/bootstrap.hack

@@ -0,0 +1,58 @@
+namespace Nuxed\Environment;
+
+use namespace Nuxed\Filesystem;
+
+/**
+ * Bootstrap your environment.
+ *
+ * Loads a .env file and the corresponding .env.local, .env.$mode and .env.$mode.local files if they exist.
+ *
+ * .env.local is always ignored in test env because tests should produce the same results for everyone.
+ * .env.dist is loaded when it exists and .env is not found.
+ *
+ * @param string  $path         A file to load
+ * @param Mode    $defaultMode  The app mode to use when none is defined
+ */
+async function bootstrap(
+  string $path,
+  Mode $defaultMode = Mode::Development,
+): Awaitable<void> {
+  $path = Filesystem\Path::create($path);
+  $dist = Filesystem\Path::create($path->toString().'.dist');
+  if ($path->exists() || !$dist->exists()) {
+    await load($path->toString());
+  } else {
+    await load($dist->toString());
+  }
+
+  $mode = mode();
+  if (null === $mode) {
+    $mode = $defaultMode;
+    put('APP_MODE', $mode);
+  }
+
+  $local = Filesystem\Path::create($path->toString().'.local');
+  if ($mode !== Mode::Test && $local->exists()) {
+    await load($local->toString());
+  }
+
+  if (Mode::Local === $mode) {
+    return;
+  }
+
+  $modeSpecific = Filesystem\Path::create($path->toString().'.'.$mode);
+  if ($modeSpecific->exists()) {
+    await load($modeSpecific->toString());
+  }
+
+  if (Mode::Test === $mode) {
+    return;
+  }
+
+  $localModeSpecifc = Filesystem\Path::create(
+    $modeSpecific->toString().'.local',
+  );
+  if ($localModeSpecifc->exists()) {
+    await load($localModeSpecifc->toString());
+  }
+}

tests/Nuxed/Environment/EnvironmentTest.hack

@@ -167,4 +167,41 @@ class EnvironmentTest extends HackTest\HackTest {
     expect(Environment\mode())
       ->toBeSame(null);
   }
+
+  public async function testBootstrap(): Awaitable<void> {
+    await Environment\bootstrap(__DIR__.'/env/dist/.env');
+    expect(Environment\contains('NE_DIST_LOADED'))
+      ->toBeTrue();
+
+    Environment\forget('APP_MODE');
+    await Environment\bootstrap(__DIR__.'/env/dev/.env');
+    expect(Environment\contains('NE_DEV_LOADED'))
+      ->toBeTrue();
+    expect(Environment\contains('NE_DEV_MODE_LOADED'))
+      ->toBeTrue();
+    expect(Environment\mode())
+      ->toBeSame(Environment\Mode::Development);
+
+    Environment\forget('APP_MODE');
+    await Environment\bootstrap(__DIR__.'/env/prod/.env');
+    expect(Environment\contains('NE_PROD_LOADED'))
+      ->toBeTrue();
+    expect(Environment\contains('NE_PROD_MODE_LOADED'))
+      ->toBeTrue();
+    expect(Environment\contains('NE_PROD_MODE_LOCAL_LOADED'))
+      ->toBeTrue();
+    expect(Environment\mode())
+      ->toBeSame(Environment\Mode::Production);
+
+    Environment\forget('APP_MODE');
+    await Environment\bootstrap(__DIR__.'/env/test/.env');
+    expect(Environment\contains('NE_TEST_LOADED'))
+      ->toBeTrue();
+    expect(Environment\contains('NE_TEST_MODE_LOADED'))
+      ->toBeTrue();
+    expect(Environment\contains('NE_TEST_MODE_LOCAL_LOADED'))
+      ->toBeFalse();
+    expect(Environment\mode())
+      ->toBeSame(Environment\Mode::Test);
+  }
 }

tests/Nuxed/Environment/env/dev/.env

@@ -0,0 +1 @@
+NE_DEV_LOADED=1

tests/Nuxed/Environment/env/dev/.env.dev

@@ -0,0 +1 @@
+NE_DEV_MODE_LOADED=1

tests/Nuxed/Environment/env/dist/.env.dist

@@ -0,0 +1 @@
+NE_DIST_LOADED=1

tests/Nuxed/Environment/env/prod/.env

@@ -0,0 +1,2 @@
+APP_MODE=prod
+NE_PROD_LOADED=1

tests/Nuxed/Environment/env/prod/.env.prod

@@ -0,0 +1 @@
+NE_PROD_MODE_LOADED=1

tests/Nuxed/Environment/env/prod/.env.prod.local

@@ -0,0 +1 @@
+NE_PROD_MODE_LOCAL_LOADED=1

tests/Nuxed/Environment/env/test/.env

@@ -0,0 +1,2 @@
+APP_MODE=test
+NE_TEST_LOADED=1

tests/Nuxed/Environment/env/test/.env.test

@@ -0,0 +1,2 @@
+
+NE_TEST_MODE_LOADED=1

tests/Nuxed/Environment/env/test/.env.test.local

@@ -0,0 +1 @@
+NE_TEST_MODE_LOCAL_LOADED=0