KMP-nmea/build.gradle.kts at master · osmandapp/KMP-nmea · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
plugins {
    kotlin("multiplatform") version "2.1.10"
    kotlin("plugin.serialization") version "2.1.10"
    id("ivy-publish")
}

group = "kotlin.nmea"
version = "0.11.1-SNAPSHOT"

repositories {
    mavenCentral()
}

kotlin {
    jvm {
        compilations.all {
            kotlinOptions.jvmTarget = "17"
        }
    }

    iosX64()
    iosArm64()
    iosSimulatorArm64()

    sourceSets {
        val commonMain by getting {
            dependencies {
                implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.8.1")
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.3")
                implementation("org.jetbrains.kotlinx:kotlinx-datetime:0.6.1")
                implementation("com.squareup.okio:okio:3.9.0")
                implementation("co.touchlab:stately-concurrent-collections:2.1.0")
            }
        }
        val commonTest by getting {
            dependencies {
                implementation(kotlin("test"))
            }
        }

        val jvmTest by getting {
            dependencies {
                implementation(kotlin("test-junit"))
                implementation("junit:junit:4.13.2")
                runtimeOnly("org.junit.vintage:junit-vintage-engine:4.12.2")
            }
        }
    }
}

publishing {
    repositories {
        ivy {
            url = uri(System.getenv("OSMAND_BINARIES_IVY_ROOT") ?: "./")
        }
    }
    publications {
        create<IvyPublication>("ivyKmpNmeaJvm") {
            organisation = project.group.toString()
            module = "kmp-nmea"
            revision = project.version.toString()
            artifact(tasks.named("jvmJar")) {
                type = "jar"
            }
            artifact(tasks.named("jvmSourcesJar")) {
                type = "jar"
                classifier = "sources"
            }
        }
    }
}