Fix crash on error detail page when using MySQL/MariaDB

Instead of using `{:array, :string}` for the `:breakcrumbs` field in `ErrorTracker.Occurrence` we use a new custom field type `ErrorTracker.Types.StringArray`.
It uses `Jason` to encode and decode arrays when storing and retrieving arrays. Therefore it works very similarly to the `:array` type but without crashing on retrieval when using MySQL/MariaDB.
This fix does not make a schema migration necessary. An additional test module `ErrorTracker.StoreFetchTest` was implemented to avoid regreessions in the future.

Fixes elixir-error-tracker#150.

Author: phihos

lib/error_tracker/schemas/occurrence.ex

@@ -18,7 +18,7 @@ defmodule ErrorTracker.Occurrence do
     field :reason, :string
 
     field :context, :map
-    field :breadcrumbs, {:array, :string}
+    field :breadcrumbs, ErrorTracker.Types.StringArray
 
     embeds_one :stacktrace, ErrorTracker.Stacktrace
     belongs_to :error, ErrorTracker.Error

lib/error_tracker/schemas/types/array.ex

@@ -0,0 +1,34 @@
+defmodule ErrorTracker.Types.StringArray do
+  @moduledoc """
+  Custom Ecto type for lists.
+
+  The built-in `:array` type is not properly implemented for the Ecto adapter `Ecto.Adapters.MyXQL`.
+  Therefore we can not use it and have to impelement our own.
+  """
+  use Ecto.Type
+
+  def type, do: {:array, :string}
+
+  def cast(list) when is_list(list) do
+    {:ok, list}
+  end
+
+  def cast(_), do: :error
+
+  def load(list) when is_binary(list) do
+    Jason.decode(list)
+  end
+
+  def load(list) do
+    {:ok, list}
+  end
+
+  def dump(list) when is_list(list) do
+    ErrorTracker.Repo.with_adapter(fn
+      :mysql -> Jason.encode(list)
+      _ -> {:ok, list}
+    end)
+  end
+
+  def dump(_), do: :error
+end

test/error_tracker/store_fetch_test.exs

@@ -0,0 +1,14 @@
+defmodule ErrorTracker.StoreFetchTest do
+  @moduledoc """
+  Test if simple store-retrieve operations are successful.
+  This is necessary, because some Ecto adapter like `Ecto.Adapters.MyXQL` may successfully store a field, but crash on retrieval.
+  """
+  use ErrorTracker.Test.Case
+
+  test "after reporting an error its occurrences should be retrievable from DB" do
+    assert %ErrorTracker.Occurrence{id: occurrence_id} =
+             report_error(fn -> raise "BOOM" end)
+
+    assert %ErrorTracker.Occurrence{} = repo().get!(ErrorTracker.Occurrence, occurrence_id)
+  end
+end