acmsg/flake.nix at main · quinneden/acmsg · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
{
  description = "Automatic git commit message generator using AI models & the OpenRouter API";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default";

    pyproject-nix = {
      url = "github:pyproject-nix/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      pyproject-nix,
      systems,
      self,
    }:
    let
      project = pyproject-nix.lib.project.loadPyproject {
        projectRoot = ./.;
      };

      inherit (project.pyproject.project) version;

      forAllSystems =
        f:
        nixpkgs.lib.genAttrs (import systems) (
          system:
          f rec {
            pkgs = import nixpkgs { inherit system; };
            python = pkgs.python312;
          }
        );
    in
    {
      apps = forAllSystems (
        { pkgs, ... }:
        {
          default = self.apps.${pkgs.system}.bump-version;
          bump-version = {
            type = "app";
            program = pkgs.lib.getExe (pkgs.callPackage ./scripts/bump-version.nix { inherit version; });
          };
        }
      );

      devShells = forAllSystems (
        { pkgs, python }:
        {
          default = pkgs.mkShell {
            packages = [
              pkgs.commitizen
              pkgs.uv
              python
            ];
          };
        }
      );

      packages = forAllSystems (
        { pkgs, python, ... }:
        {
          default = self.packages.${pkgs.system}.acmsg;
          acmsg =
            let
              attrs = project.renderers.buildPythonPackage { inherit python; };
            in
            python.pkgs.buildPythonPackage attrs;
        }
      );

      overlays.default = (
        final: prev: {
          acmsg = self.packages.${prev.system}.acmsg;
        }
      );
    };
}