10_Life_expectancy.bc2

1000 A=200:GOTO20:REM  LIFE EXPECTANCY
1010 GOSUB100
1020 PRINT" LIFE EXPECTANCY GAME "
1030 PRINT
1040 PRINT" THIS TEST WILL DETERMINE HOW OLD YOU"
1045 PRINT
1050 PRINT" WILL BECOME. IT ASSUMES THAT"
1055 PRINT
1060 PRINT" YOU ARE IN GOOD HEALTH AND BETWEEN"
1065 PRINT
1070 PRINT" 20 AND 65 YEARS OLD."
1072 PRINT
1075 PRINT" G O O D  L U C K ! "
1080 FORI=1 TO6000
1090 NEXTI
1100 S=72
1110 GOSUB100
1120 PRINT"SEX"
1130 PRINT
1140 PRINT
1150 PRINT"ARE YOU A MAN OR A WOMAN? (PUSH M OR W)"
1160 GOSUB210
1170 IFIN$<>"M" ANDIN$<>"W" THEN1160
1180 IFIN$="M" THENS=S-3
1190 IFIN$="W" THENS=S+4
1200 G$=IN$
1210 GOSUB100
1220 PRINT"LIFE STYLE."
1230 PRINT
1240 PRINT"DO YOU LIVE IN OR NEAR A CITY"
1245 PRINT
1250 PRINT"WITH A POPULATION GREATER THAN 500,000?"
1260 PRINT
1265 PRINT"Y=YES    N=NO"
1267 PRINT
1270 GOSUB210
1280 IFIN$<>"Y" ANDIN$<>"N" THEN1270
1290 IFIN$="Y" THENS=S-2
1300 IFIN$="N" THEN1350
1310 PRINT"CITY LIFE EXPOSES YOU TO GREATER LEVELS"
1320 PRINT"OF STRESS AND AIR POLLUTION ! "
1330 PRINT
1340 GOTO1410
1350 PRINT"DO YOU LIVE IN AN AREA WITH LESS THAN"
1355 PRINT
1360 PRINT"10,000 INHABITANTS OR IN OPEN COUNTRY?"
1370 PRINT
1380 GOSUB210
1390 IFIN$<>"Y" ANDIN$<>"N" THEN1380
1400 IFIN$="Y" THENS=S+2
1405 PRINT
1410 PRINT"WORK ENVIRONMENT."
1415 PRINT
1420 PRINT"DOES YOUR JOB INVOLVE A LOT OF"
1422 PRINT
1425 PRINT"SITTING DOWN?"
1427 PRINT
1430 GOSUB210
1440 IFIN$<>"Y" ANDIN$<>"N" THEN1430
1450 IFIN$="Y" THENS=S-3
1460 IFIN$="N" THEN1480
1470 GOTO1540
1480 PRINT"DOES YOUR JOB INVOLVE HEAVY PHYSICAL"
1490 PRINT"ACTIVITY?"
1500 PRINT
1510 GOSUB210
1520 IFIN$<>"Y" ANDIN$<>"N" THEN1510
1530 IFIN$="Y" THENS=S+3
1540 PRINT
1545 PRINT"DO YOU EXCERCISE 4 TIMES A WEEK"
1550 PRINT"OR MORE (E.G. JOGGING, SWIMMING) ?"
1560 GOSUB210
1570 IFIN$<>"Y" ANDIN$<>"N" THEN1560
1580 IFIN$="Y" THENS=S+2
1590 GOSUB100
1600 PRINT"LIFESTYLE."
1610 PRINT
1620 PRINT
1630 PRINT"DO YOU LIVE TOGETHER WITH ANOTHER PERSON?"
1640 PRINT
1650 GOSUB210
1660 IFIN$<>"Y" ANDIN$<>"N" THEN1650
1670 IFIN$="Y" THENS=S+5
1680 IFIN$="N" THEN1750
1690 PRINT"PEOPLE WHO LIVE TOGETHER ARE LESS"
1700 PRINT"DEPRESSIVE, EAT BETTER,"
1710 PRINT"AND TEND TO LOOK AFTER EACH OTHER !"
1720 FORI=1 TO6000
1730 NEXTI
1740 GOTO1820
1750 PRINT"HOW MANY YEARS HAVE YOU BEEN SINGLE"
1755 PRINT"SINCE YOUR 25TH BIRTHDAY?"
1760 INPUTY
1770 IFY<10 THENY=1
1780 IFY>9 ANDY<20 THENY=2
1790 IFY>19 ANDY<30 THENY=3
1800 IFY>29 THENY=4
1810 S=S-Y
1820 GOSUB100
1830 PRINT"PERSONAL DETAILS."
1840 PRINT
1850 PRINT"DO YOU SLEEP MORE THAN 10 HRS A NIGHT?"
1860 PRINT
1870 GOSUB210
1880 IFIN$<>"Y" ANDIN$<>"N" THEN1870
1890 IFIN$="Y" THENS=S-4
1900 IFIN$="N" THEN1950
1910 PRINT"ABNORMALLY LONG SLEEP IS AN"
1920 PRINT"INDICATION OF POOR CIRCULATION"
1930 PRINT"OR DEPRESSION !"
1940 PRINT
1950 PRINT"DO YOU LOSE YOUR TEMPER QUICKLY"
1955 PRINT"OR ARE YOU AGRESSIVE?"
1960 PRINT
1970 GOSUB210
1980 IFIN$<>"Y" ANDIN$<>"N" THEN1970
1990 IFIN$="Y" THENS=S-3
2000 IFIN$="N" THEN2020
2010 GOTO2070
2020 PRINT"ARE YOU GENERALLY CALM & RELAXED?"
2030 PRINT
2040 GOSUB210
2050 IFIN$<>"Y" ANDIN$<>"N" THEN2040
2060 IFIN$="Y" THENS=S+3
2070 PRINT"ARE YOU GENERALLY HAPPY?"
2080 PRINT
2090 GOSUB210
2100 IFIN$<>"Y" ANDIN$<>"N" THEN2090
2110 IFIN$="Y" THENS=S+1
2120 IFIN$="N" THEN2140
2130 GOTO2190
2140 PRINT"ARE YOU OFTEN EMOTIONALLY UPSET?"
2150 PRINT
2160 GOSUB210
2170 IFIN$<>"Y" ANDIN$<>"N" THEN2160
2180 IFIN$="Y" THENS=S-2
2190 GOSUB100
2200 PRINT"PERSONALITY."
2210 PRINT
2220 PRINT
2230 PRINT"HAVE YOU BEEN FINED FOR SPEEDING"
2240 PRINT"IN THE LAST 12 MONTHS?"
2245 PRINT
2250 GOSUB210
2260 IFIN$<>"Y" ANDIN$<>"N" THEN2250
2270 IFIN$="N" THEN2330
2280 PRINT"TRAFFIC ACCIDENTS ARE ONE OF THE"
2290 PRINT"MAJOR CAUSES OF DEATH AMONGST"
2295 PRINT"YOUNG ADULTS !"
2297 PRINT
2300 FORI=1 TO5000
2310 NEXTI
2320 S=S-1
2330 GOSUB100
2340 PRINT"ACHIEVEMENT."
2350 PRINT
2360 PRINT
2370 PRINT"DO YOU EARN MORE THAN "
2380 PRINT"25,000 POUNDS A YEAR?"
2385 PRINT
2390 GOSUB210
2400 IFIN$<>"Y" ANDIN$<>"N" THEN2390
2410 IFIN$="N" THEN2460
2420 S=S-2
2430 PRINT"WEALTH AND STRESS OFTEN"
2440 PRINT"GO TOGETHER !"
2450 PRINT
2460 PRINT"DO YOU HAVE A TITLE (BSC,BA,DR,ETC) ?"
2470 PRINT
2480 GOSUB210
2490 IFIN$<>"Y" ANDIN$<>"N" THEN2480
2500 IFIN$="N" THEN2600
2510 PRINT"GOOD EDUCATION OFTEN HELPS"
2520 PRINT"TO PLAN ONES LIFE BETTER."
2530 PRINT
2540 S=S+1
2550 PRINT"DO YOU HAVE A RANK OR A RESPONSIBLE JOB?"
2560 PRINT
2570 GOSUB210
2580 IFIN$<>"Y" ANDIN$<>"N" THEN2570
2590 IFIN$="Y" THENS=S+2
2600 GOSUB100
2610 PRINT"MORE PERSONAL DETAILS."
2620 PRINT
2630 PRINT
2640 PRINT"IF YOU ARE 65, DO YOU"
2650 PRINT"STILL WORK?"
2660 PRINT
2670 GOSUB210
2680 IFIN$<>"Y" ANDIN$<>"N" THEN2670
2690 IFIN$="Y" THENS=S+3
2700 IFIN$="N" THEN2740
2710 PRINT"OVERWORK IS ALSO A KILLER !"
2720 FORI=1 TO4000
2730 NEXTI
2740 GOSUB100
2750 PRINT"FAMILY TREE."
2760 PRINT
2770 PRINT
2780 PRINT"DID ONE OF YOUR GRANDPARENTS LIVE"
2790 PRINT"LONGER THAN 70 YEARS?"
2800 PRINT
2810 GOSUB210
2820 IFIN$<>"Y" ANDIN$<>"N" THEN2810
2830 IFIN$="N" THEN2910
2840 PRINT"DID ALL YOUR GRANDPARENTS LIVE"
2850 PRINT"TO BE 80 YEARS OR OLDER?"
2860 PRINT
2870 GOSUB210
2880 IFIN$<>"Y" ANDIN$<>"N" THEN2870
2890 IFIN$="Y" THENS=S+6
2900 IFIN$="N" THENS=S+2
2910 PRINT
2915 PRINT"DID ONE OF YOUR PARENTS DIE"
2920 PRINT"OF A HEART ATTACK OR STROKE"
2930 PRINT"BEFORE HIS/HER 50TH BIRTHDAY?"
2935 PRINT
2940 GOSUB210
2950 IFIN$<>"Y" ANDIN$<>"N" THEN2940
2960 IFIN$="Y" THENS=S-4
2970 PRINT
2975 PRINT"HAS ANY ONE OF YOUR PARENTS, BROTHERS"
2980 PRINT"OR SISTERS SUFFERED FROM"
2990 PRINT"A HEART ATTACK, CANCER, OR"
3000 PRINT"DIABETES BEFORE THEIR 50TH BIRTHDAY?"
3005 PRINT
3010 GOSUB210
3020 IFIN$<>"Y" ANDIN$<>"N" THEN3010
3030 IFIN$="Y" THENS=S-3
3040 GOSUB100
3050 PRINT"HEALTH"
3060 PRINT
3070 PRINT"DO YOU SMOKE CIGARETTES?"
3080 PRINT
3090 GOSUB210
3100 IFIN$<>"Y" ANDIN$<>"N" THEN3090
3110 IFIN$="N" THEN3260
3120 PRINT"DO YOU SMOKE MORE THAN 40 A DAY?"
3130 GOSUB210
3140 IFIN$<>"Y" ANDIN$<>"N" THEN3130
3150 IFIN$="Y" THEN3220
3160 PRINT"DO YOU SMOKE BETWEEN 20 AND 40 A DAY?"
3170 GOSUB210
3180 IFIN$<>"Y" ANDIN$<>"N" THEN3170
3190 IFIN$="Y" THEN3240
3200 S=S-3
3210 GOTO3260
3220 S=S-8
3230 GOTO3260
3240 S=S-6
3250 GOTO3260
3260 PRINT
3270 PRINT"DO YOU DRINK SPIRITS IN MODERATE AMOUNTS?"
3280 PRINT
3290 GOSUB210
3300 IFIN$<>"Y" ANDIN$<>"N" THEN3290
3310 IFIN$="Y" THENS=S-1
3320 PRINT"ARE YOU OVERWEIGHT?"
3330 PRINT
3340 GOSUB210
3350 IFIN$<>"Y" ANDIN$<>"N" THEN3340
3360 IFIN$="N" THEN3550
3370 PRINT"ARE YOU MORE THAN 25 KILOS OVERWEIGHT?"
3375 PRINT
3380 GOSUB210
3390 IFIN$<>"Y" ANDIN$<>"N" THEN3380
3400 IFIN$="Y" THEN3500
3410 PRINT"ARE YOU BETWEEN 15 AND 25"
3415 PRINT"KILOS OVERWEIGHT?"
3417 PRINT
3420 GOSUB210
3430 IFIN$<>"Y" ANDIN$<>"N" THEN3420
3440 IFIN$="Y" THEN3520
3450 PRINT"ARE YOU BETWEEN 5 AND 15"
3455 PRINT"KILOS OVERWEIGHT?"
3457 PRINT
3460 GOSUB210
3470 IFIN$<>"Y" ANDIN$<>"N" THEN3460
3480 IFIN$="Y" THEN3540
3490 IFIN$="N" THEN3550
3500 S=S-8
3510 GOTO3550
3520 S=S-4
3530 GOTO3550
3540 S=S-2
3550 GOSUB100
3560 PRINT"PRESENT AGE."
3570 PRINT
3580 PRINT
3590 A=30
3600 PRINT"ARE YOU BELOW 30? (NO FIBS PLEASE!)"
3610 GOSUB210
3620 IFIN$<>"Y" ANDIN$<>"N" THEN3610
3630 IFIN$="Y" THEN3910
3640 PRINT
3650 PRINT"ARE YOU BETWEEN 30 AND 40 YEARS OLD?"
3660 GOSUB210
3670 IFIN$<>"Y" ANDIN$<>"N" THEN3660
3680 IFIN$="N" THEN3720
3690 A=39
3700 S=S+2
3710 GOTO3910
3720 PRINT
3730 PRINT"ARE YOU BETWEEN 40 AND 50?"
3740 GOSUB210
3750 IFIN$<>"Y" ANDIN$<>"N" THEN3740
3760 IFIN$="N" THEN3800
3770 A=49
3780 S=S+3
3790 GOTO3910
3800 PRINT
3810 PRINT"ARE YOU BETWEEN 50 AND 70?"
3820 GOSUB210
3830 IFIN$<>"Y" ANDIN$<>"N" THEN3820
3840 IFIN$="N" THEN3880
3850 A=70
3860 S=S+4
3870 GOTO3910
3880 A=71
3890 PRINT
3900 PRINT"I ASSUME YOU'RE OLDER THEN 70 THEN."
3902 PRINT
3905 PRINT"YOU DIDN'T READ THE FIRST PAGE!"
3910 IFG$="M" THEN3990
3920 PRINT
3930 PRINT"DO YOU VISIT A GYNAECOLOGIST"
3940 PRINT"AT LEAST ONCE A YEAR?"
3950 GOSUB210
3960 IFIN$<>"Y" ANDIN$<>"N" THEN3950
3970 IFIN$="Y" THENS=S+2
3980 GOTO4050
3990 IFA<=40 THEN4050
4000 PRINT
4010 PRINT"DO YOU HAVE AN ANNUAL MEDICAL CHECK-UP?"
4020 GOSUB210
4030 IFIN$<>"Y" ANDIN$<>"N" THEN4020
4040 IFIN$="Y" THENS=S+2
4050 IFS>=60 ANDS<65 THEN4130
4060 IFS>=65 ANDS<70 THEN4180
4070 IFS>=70 ANDS<75 THEN4230
4080 IFS>=75 ANDS<80 THEN4280
4090 IFS>=80 ANDS<85 THEN4330
4100 IFS>=85 ANDS<90 THEN4380
4110 IFS>=90 ANDS<95 THEN4430
4120 IFS>=95 THEN4480
4130 B=26
4140 B1=35
4150 G=15
4160 G1=19
4170 GOTO4530
4180 B=36
4190 B1=47
4200 G=20
4210 G1=29
4220 GOTO4530
4230 B=48
4240 B1=60
4250 G=30
4260 G1=38
4270 GOTO4530
4280 B=61
4290 B1=74
4300 G=39
4310 G1=52
4320 GOTO4530
4330 B=75
4340 B1=86
4350 G=53
4360 G1=69
4370 GOTO4530
4380 B=87
4390 B1=95
4400 G=70
4410 G1=87
4420 GOTO4530
4430 B=96
4440 B1=98
4450 G=88
4460 G1=96
4470 GOTO4530
4480 B=99
4490 B1=99.9
4500 G=97
4510 G1=99.6
4520 GOTO4530
4530 IF(S<A) THEN4740
4540 GOSUB100
4550 PRINT
4560 PRINT"I PREDICT THAT YOU SHOULD REACH"
4570 PRINTS;" YEARS OF AGE."
4580 IFS<60 THEN4660
4590 PRINT
4600 PRINT
4610 PRINT
4620 PRINT"THIS MEANS YOU WILL BE OLDER THAN"
4630 PRINT"BETWEEN ";B;" AND ";B1;" % OF THE AVERAGE AGE"
4640 PRINT"FOR MEN, AND ";G;" TO ";G1;"% OF THE AVERAGE"
4650 PRINT"AGE FOR WOMEN."
4660 PRINT
4670 PRINT
4680 PRINT"DO YOU WANT TO RUN THE"
4690 PRINT"TEST AGAIN? (Y/N) ?"
4700 GOSUB210
4710 IFIN$<>"Y" ANDIN$<>"N" THEN4700
4720 IFIN$="N" THENEND
4730 GOTO1010
4740 GOSUB100
4750 PRINT"I DON'T KNOW HOW YOU MANAGED TO FINISH"
4760 PRINT"BECAUSE YOU SHOULD HAVE ALREADY BEEN"
4765 PRINT"DEAD FOR AGES !!"
4770 GOTO4660
30000 REM
30010 REM LIFE EXPECTANCY VERSION 2.7 COMPILED 12.01.84
30020 REM DUTCH LANGUAGE ORIGINAL WRITTEN BY
30025 REM PETER WILKES, P.O.BOX 8720
30030 REM EINDHOVEN, THE NETHERLANDS.
30040 REM ON A TRS-80 MODEL 1.
30050 REM TRANSLATED FOR
30055 REM RADIO NETHERLANDS
30060 REM BY JONATHAN MARKS, HILVERSUM.