Lesson 9: Error: VM Exception while processing transaction: reverted with an unrecognized custom error

[AmethRP]

Hi team,

I'm getting the below error when trying to do my unit tests which should revert when the raffle is calculating.

"Error: VM Exception while processing transaction: reverted with an unrecognized custom error"

Based on my console logs, it does not get beyond the performUpkeep section of my test.

I've tried a few things without any success. Even when using 'to.be.revertedWithCustomError', I still get the same error message for some reason. Any help would be greatly appreciated. Please let me know if you require any further information.

My test script:

const { getNamedAccounts, deployments, ethers, network } = require("hardhat")
const { developmentChains, networkConfig } = require("../../helper-hardhat-config")
const { assert, expect } = require("chai")

describe("Raffle Unit Tests", function () {
    if (!developmentChains.includes(network.name)) {
        console.log(`Skipping Raffle Unit Tests for network: ${network.name}`)
        return
    }

    let raffle, VRFCoordinatorV2Mock, raffleEntranceFee, deployer, interval
    const chainId = network.config.chainId

    beforeEach(async function () {
        deployer = (await getNamedAccounts()).deployer
        await deployments.fixture(["all"])
        raffle = await ethers.getContract("Raffle", deployer)
        VRFCoordinatorV2Mock = await ethers.getContract("VRFCoordinatorV2Mock", deployer)
        raffleEntranceFee = await raffle.getEntranceFee()
        interval = await raffle.getInterval()
    })

    describe("constructor", function () {
        it("initialises the raffle correctly", async function () {
            const raffleState = await raffle.getRaffleState()
            const interval = await raffle.getInterval()
            assert.equal(raffleState.toString(), "0")
            assert.equal(interval.toString(), networkConfig[chainId]["interval"])
        })
    })

    describe("enterRaffle", async function () {
        it("reverts when you dont pay enough", async function () {
            await expect(raffle.enterRaffle()).to.be.revertedWith("Raffle__NotEnoughETHEntered")
        })
        it("records players when they enter", async function () {
            await raffle.enterRaffle({ value: raffleEntranceFee })
            const playerFromContract = await raffle.getPlayer(0)
            assert.equal(playerFromContract, deployer)
        })
        it("emits event on enter", async function () {
            await expect(raffle.enterRaffle({ value: raffleEntranceFee })).to.emit(
                raffle,
                "RaffleEnter"
            )
        })
        it("doesnt allow entrance when raffle is calculating", async function () {
            await raffle.enterRaffle({ value: raffleEntranceFee })
            console.log("raffle entered")
            await network.provider.send("evm_increaseTime", [interval.toNumber() + 1])
            console.log("time passed")
            await network.provider.send("evm_mine", [])
            console.log("block mined")
            // we pretend to be a chainlink keeper
            await raffle.performUpkeep([])
            console.log("state changed to calculating")
            await expect(raffle.enterRaffle({ value: raffleEntranceFee })).to.be.revertedWith(
                "Raffle__NotOpen"
            )
        })
    })
})

My Raffle.sol contract:

pragma solidity ^0.8.7;

import "@chainlink/contracts/src/v0.8/VRFConsumerBaseV2.sol";
import "@chainlink/contracts/src/v0.8/interfaces/VRFCoordinatorV2Interface.sol";
import "@chainlink/contracts/src/v0.8/interfaces/AutomationCompatibleInterface.sol";

error Raffle__NotEnoughETHEntered();
error Raffle__TransferFailed();
error Raffle__NotOpen();
error Raffle__UpkeepNotNeeded(uint256 currentBalance, uint256 numPlayers, uint256 raffleState);

contract Raffle is VRFConsumerBaseV2, AutomationCompatibleInterface {
    // types
    enum RaffleState {
        OPEN,
        CALCULATING
    }

    uint256 private immutable i_entranceFee;
    address payable[] private s_players;
    VRFCoordinatorV2Interface private immutable i_vrfCoordinator;
    bytes32 private immutable i_gasLane;
    uint64 private immutable i_subscriptionId;
    uint16 private constant REQUEST_CONFIRMATIONS = 3;
    uint32 private immutable i_callbackGasLimit;
    uint32 private constant NUM_WORDS = 1;

    // Lottery variables
    address private s_recentWinner;
    RaffleState private s_raffleState;
    uint256 private s_lastTimeStamp;
    uint256 private immutable i_interval;

    // Events
    event RaffleEnter(address indexed player);
    event RequestedRaffleWinner(uint256 indexed requestId);
    event WinnerPicked(address indexed winner);

    constructor(
        address vrfCoordinatorV2,
        uint256 entranceFee,
        bytes32 gasLane,
        uint64 subscriptionId,
        uint32 callbackGasLimit,
        uint256 interval
    ) VRFConsumerBaseV2(vrfCoordinatorV2) {
        i_entranceFee = entranceFee;
        i_vrfCoordinator = VRFCoordinatorV2Interface(vrfCoordinatorV2);
        i_gasLane = gasLane;
        i_subscriptionId = subscriptionId;
        i_callbackGasLimit = callbackGasLimit;
        s_raffleState = RaffleState.OPEN;
        s_lastTimeStamp = block.timestamp;
        i_interval = interval;
    }

    function enterRaffle() public payable {
        // require msg.value > i_entranceFee
        if (msg.value < i_entranceFee) {
            revert Raffle__NotEnoughETHEntered();
        }
        if (s_raffleState != RaffleState.OPEN) {
            revert Raffle__NotOpen();
        }
        s_players.push(payable(msg.sender));
        // emit an event when we update a dynamic array or mapping
        // name events with the function name reversed
        emit RaffleEnter(msg.sender);
    }

    // the function that Chainlink keeper nodes call and the look for the upkeep needed
    function checkUpkeep(
        bytes memory
    ) public view override returns (bool upkeepNeeded, bytes memory) {
        bool isOpen = (RaffleState.OPEN == s_raffleState);
        bool timePassed = ((block.timestamp - s_lastTimeStamp) > i_interval);
        bool hasPlayers = (s_players.length > 0);
        bool hasBalance = address(this).balance > 0;
        upkeepNeeded = (isOpen && timePassed && hasPlayers && hasBalance);
    }

    function performUpkeep(bytes calldata) external override {
        (bool upkeepNeeded, ) = checkUpkeep("");
        if (!upkeepNeeded) {
            revert Raffle__UpkeepNotNeeded(
                address(this).balance,
                s_players.length,
                uint256(s_raffleState)
            );
        }
        // request the random number
        // once we get it, do something with it
        // 2 transaction process
        s_raffleState = RaffleState.CALCULATING;
        uint256 requestId = i_vrfCoordinator.requestRandomWords(
            i_gasLane,
            i_subscriptionId,
            REQUEST_CONFIRMATIONS,
            i_callbackGasLimit,
            NUM_WORDS
        );
        emit RequestedRaffleWinner(requestId);
    }

    function fulfillRandomWords(
        uint256 /* requestID */,
        uint256[] memory randomWords
    ) internal override {
        uint256 indexOfWinner = randomWords[0] % s_players.length;
        address payable recentWinner = s_players[indexOfWinner];
        s_recentWinner = recentWinner;
        s_raffleState = RaffleState.OPEN;
        s_players = new address payable[](0);
        s_lastTimeStamp = block.timestamp;
        (bool success, ) = recentWinner.call{value: address(this).balance}("");
        if (!success) {
            revert Raffle__TransferFailed();
        }
        emit WinnerPicked(recentWinner);
    }

    function getEntranceFee() public view returns (uint256) {
        return i_entranceFee;
    }

    function getPlayer(uint256 index) public view returns (address) {
        return s_players[index];
    }

    function getRecentWinner() public view returns (address) {
        return s_recentWinner;
    }

    function getRaffleState() public view returns (RaffleState) {
        return s_raffleState;
    }

    function getNumWords() public pure returns (uint256) {
        return NUM_WORDS;
    }

    function getNumberOfPlayers() public view returns (uint256) {
        return s_players.length;
    }

    function getLatestTimeStamp() public view returns (uint256) {
        return s_lastTimeStamp;
    }

    function getRequestedConfirmations() public pure returns (uint256) {
        return REQUEST_CONFIRMATIONS;
    }

    function getInterval() public view returns (uint256) {
        return i_interval;
    }
}

[alymurtazamemon]

@AmethRP Please show the terminal error.

[AmethRP]

Still getting the exact same error message with:
await expect(raffle.enterRaffle({ value: raffleEntranceFee })).to.be.revertedWithCustomError(raffle, "Raffle__NotOpen");

[alymurtazamemon]

@AmethRP Can I have the repo link, please?

[AmethRP]

https://github.com/AmethRP/FCC-lottery-L9/tree/main

Thank you so much for your help! Been stuck on this all day.

[alymurtazamemon]

@AmethRP The solution I just was for the latest version of chai matcher which comes built-in with hardhat-toolbox dependency.

But for your version this is working;

await expect(raffle.enterRaffle({ value: raffleEntranceFee })).to.be.revertedWith(
    "Raffle__NotOpen"
)

Try to remove both .lock files and node_modules folder and reinstall dependencies and then retry.

[AmethRP]

Hi, thanks again for your help!

I'm still having the same issue when removing the .lock files and node_modules folder, then reinstalling dependencies using yarn install. I've also tried downloading the repo from github and doing it on that folder but still to no avail. Do you have any other suggestions for how I can make this run on my machine?

[alymurtazamemon]

@AmethRP I have sent the pull request to your repository of working code, you can merge it and try.

[AmethRP]

Thanks again! managed to fix this error and then got the 'InvalidConsumer()' error but managed to fix that from solutions online. You're an absolute legend!

[Glow-in-the-dark]

Hey @AmethRP & @alymurtazamemon I happen to have the same issue.
AmethRP, how did u fix the "invalid Consumer()' Error ? i had the same issue. Can u show me the online solution ?

My repo: https://github.com/Glow-in-the-dark/Solidity-playground/tree/main/EtherJS_Hardhat/hardhat-smartcontract-lottery/contracts