build: create Depends build type for depends and use it by default

Rather than modifying the existing build types and adding flags for each,
create a new type specifically for depends.

This allows the forwarding of optional flags into the CMake build for the
"Depends" build type, but the user can now optionally use an existing
(Debug/RelWitDebInfo/etc.) type to ignore the optimization flags set by depends
and use the ones from that type instead.

As an example, a user may do:
make -C depends
cmake --toolchain depends/arm64-apple-darwin/toolchain.cmake -DCMAKE_BUILD_TYPE=Debug

This would compile depends with the default optimization flags for depends
(-O2) but build Core with the default optimization flags from CMake.

Depends note:
For hosts, $host_*FLAGS variables now represent the mandatory flags for
compiling and will be forwarded to all Core builds in the toolchain file,
regardless of the build type. For most platforms they should be empty, but
are useful at least for darwin.

When setting (for example) CFLAGS from the command line when building depends,
these flags will be stored in $host_release_CFLAGS (or _debug_), and will only
be forwarded to the Depends build type.

Author: theuni

CMakeLists.txt

@@ -201,10 +201,10 @@ check_linker_supports_pie(configure_warnings)
 # It is a usage requirement for all targets except for secp256k1, which
 # gets its flags by other means.
 add_library(core_interface INTERFACE)
-add_library(core_interface_relwithdebinfo INTERFACE)
+add_library(core_interface_depends INTERFACE)
 add_library(core_interface_debug INTERFACE)
 target_link_libraries(core_interface INTERFACE
-  $<$<CONFIG:RelWithDebInfo>:core_interface_relwithdebinfo>
+  $<$<CONFIG:Depends>:core_interface_depends>
   $<$<CONFIG:Debug>:core_interface_debug>
 )
 
@@ -572,8 +572,7 @@ else()
 endif()
 
 target_compile_definitions(core_interface INTERFACE ${DEPENDS_COMPILE_DEFINITIONS})
-target_compile_definitions(core_interface_relwithdebinfo INTERFACE ${DEPENDS_COMPILE_DEFINITIONS_RELWITHDEBINFO})
-target_compile_definitions(core_interface_debug INTERFACE ${DEPENDS_COMPILE_DEFINITIONS_DEBUG})
+target_compile_definitions(core_interface_depends INTERFACE ${DEPENDS_CONFIG_COMPILE_DEFINITIONS})
 
 # If the {CXX,LD}FLAGS environment variables are defined during building depends
 # and configuring this build system, their content might be duplicated.

depends/Makefile

@@ -218,17 +218,13 @@ $(host_prefix)/toolchain.cmake : toolchain.cmake.in $(host_prefix)/.stamp_$(fina
             -e 's|@OBJCOPY@|$(host_OBJCOPY)|' \
             -e 's|@OBJDUMP@|$(host_OBJDUMP)|' \
             -e 's|@CFLAGS@|$(strip $(host_CFLAGS))|' \
-            -e 's|@CFLAGS_RELEASE@|$(strip $(host_release_CFLAGS))|' \
-            -e 's|@CFLAGS_DEBUG@|$(strip $(host_debug_CFLAGS))|' \
+            -e 's|@CFLAGS_DEPENDS_CONFIG@|$(strip $(host_$(release_type)_CFLAGS))|' \
             -e 's|@CXXFLAGS@|$(strip $(host_CXXFLAGS))|' \
-            -e 's|@CXXFLAGS_RELEASE@|$(strip $(host_release_CXXFLAGS))|' \
-            -e 's|@CXXFLAGS_DEBUG@|$(strip $(host_debug_CXXFLAGS))|' \
+            -e 's|@CXXFLAGS_DEPENDS_CONFIG@|$(strip $(host_$(release_type)_CXXFLAGS))|' \
             -e 's|@CPPFLAGS@|$(strip $(host_CPPFLAGS))|' \
-            -e 's|@CPPFLAGS_RELEASE@|$(strip $(host_release_CPPFLAGS))|' \
-            -e 's|@CPPFLAGS_DEBUG@|$(strip $(host_debug_CPPFLAGS))|' \
+            -e 's|@CPPFLAGS_DEPENDS_CONFIG@|$(strip $(host_$(release_type)_CPPFLAGS))|' \
             -e 's|@LDFLAGS@|$(strip $(host_LDFLAGS))|' \
-            -e 's|@LDFLAGS_RELEASE@|$(strip $(host_release_LDFLAGS))|' \
-            -e 's|@LDFLAGS_DEBUG@|$(strip $(host_debug_LDFLAGS))|' \
+            -e 's|@LDFLAGS_DEPENDS_CONFIG@|$(strip $(host_$(release_type)_LDFLAGS))|' \
             -e 's|@qt_packages@|$(qt_packages_)|' \
             -e 's|@qrencode_packages@|$(qrencode_packages_)|' \
             -e 's|@zmq_packages@|$(zmq_packages_)|' \

depends/toolchain.cmake.in

@@ -15,14 +15,27 @@ if(@depends_crosscompiling@)
   set(CMAKE_SYSTEM_PROCESSOR @host_arch@)
 endif()
 
+
+# Create a build type specifically for depends builds and default to it. When
+# building from depends toolchain file, this will ensure that the flags from
+# depends (or those provided by the user during depends build) will not be
+# overridden by CMake's build-type flags.
+# The user can still change the build-type to a non-Depends-type
+# (Release/Debug/RelWithDebInfo/etc), which will inform the build to ignore the
+# depends flags.
+if(NOT SET_UP_CONFIGURATIONS_DONE)
+    set(SET_UP_CONFIGURATIONS_DONE TRUE)
+    list(PREPEND CMAKE_CONFIGURATION_TYPES "Depends")
+    if(NOT CMAKE_BUILD_TYPE)
+      set(CMAKE_BUILD_TYPE Depends)
+    endif()
+endif()
+
 if(NOT DEFINED CMAKE_C_FLAGS_INIT)
   set(CMAKE_C_FLAGS_INIT "@CFLAGS@")
 endif()
-if(NOT DEFINED CMAKE_C_FLAGS_RELWITHDEBINFO_INIT)
-  set(CMAKE_C_FLAGS_RELWITHDEBINFO_INIT "@CFLAGS_RELEASE@")
-endif()
-if(NOT DEFINED CMAKE_C_FLAGS_DEBUG_INIT)
-  set(CMAKE_C_FLAGS_DEBUG_INIT "@CFLAGS_DEBUG@")
+if(NOT DEFINED CMAKE_C_FLAGS_DEPENDS_INIT)
+  set(CMAKE_C_FLAGS_DEPENDS_INIT "@CFLAGS_DEPENDS_CONFIG@")
 endif()
 
 if(NOT DEFINED CMAKE_C_COMPILER)
@@ -33,13 +46,9 @@ if(NOT DEFINED CMAKE_CXX_FLAGS_INIT)
   set(CMAKE_CXX_FLAGS_INIT "@CXXFLAGS@")
   set(CMAKE_OBJCXX_FLAGS_INIT "@CXXFLAGS@")
 endif()
-if(NOT DEFINED CMAKE_CXX_FLAGS_RELWITHDEBINFO_INIT)
-  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO_INIT "@CXXFLAGS_RELEASE@")
-  set(CMAKE_OBJCXX_FLAGS_RELWITHDEBINFO_INIT "@CXXFLAGS_RELEASE@")
-endif()
-if(NOT DEFINED CMAKE_CXX_FLAGS_DEBUG_INIT)
-  set(CMAKE_CXX_FLAGS_DEBUG_INIT "@CXXFLAGS_DEBUG@")
-  set(CMAKE_OBJCXX_FLAGS_DEBUG_INIT "@CXXFLAGS_DEBUG@")
+if(NOT DEFINED CMAKE_CXX_FLAGS_DEPENDS_INIT)
+  set(CMAKE_CXX_FLAGS_DEPENDS_INIT "@CXXFLAGS_DEPENDS_CONFIG@")
+  set(CMAKE_OBJCXX_FLAGS_DEPENDS_INIT "@CXXFLAGS_DEPENDS_CONFIG@")
 endif()
 
 if(NOT DEFINED CMAKE_CXX_COMPILER)
@@ -49,26 +58,19 @@ endif()
 
 # The DEPENDS_COMPILE_DEFINITIONS* variables are to be treated as lists.
 set(DEPENDS_COMPILE_DEFINITIONS @CPPFLAGS@)
-set(DEPENDS_COMPILE_DEFINITIONS_RELWITHDEBINFO @CPPFLAGS_RELEASE@)
-set(DEPENDS_COMPILE_DEFINITIONS_DEBUG @CPPFLAGS_DEBUG@)
+set(DEPENDS_CONFIG_COMPILE_DEFINITIONS @CPPFLAGS_DEPENDS_CONFIG@)
 
 if(NOT DEFINED CMAKE_EXE_LINKER_FLAGS_INIT)
   set(CMAKE_EXE_LINKER_FLAGS_INIT "@LDFLAGS@")
 endif()
 if(NOT DEFINED CMAKE_SHARED_LINKER_FLAGS_INIT)
   set(CMAKE_SHARED_LINKER_FLAGS_INIT "@LDFLAGS@")
 endif()
-if(NOT DEFINED CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO_INIT)
-  set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO_INIT "@LDFLAGS_RELEASE@")
-endif()
-if(NOT DEFINED CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO_INIT)
-  set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO_INIT "@LDFLAGS_RELEASE@")
-endif()
-if(NOT DEFINED CMAKE_EXE_LINKER_FLAGS_DEBUG_INIT)
-  set(CMAKE_EXE_LINKER_FLAGS_DEBUG_INIT "@LDFLAGS_DEBUG@")
+if(NOT DEFINED CMAKE_SHARED_LINKER_FLAGS_DEPENDS_INIT)
+  set(CMAKE_SHARED_LINKER_FLAGS_DEPENDS_INIT "@LDFLAGS_DEPENDS_CONFIG@")
 endif()
-if(NOT DEFINED CMAKE_SHARED_LINKER_FLAGS_DEBUG_INIT)
-  set(CMAKE_SHARED_LINKER_FLAGS_DEBUG_INIT "@LDFLAGS_DEBUG@")
+if(NOT DEFINED CMAKE_EXE_LINKER_FLAGS_DEPENDS_INIT)
+  set(CMAKE_EXE_LINKER_FLAGS_DEPENDS_INIT "@LDFLAGS_DEPENDS_CONFIG@")
 endif()
 
 set(CMAKE_AR "@AR@")