website/main.v at master · vlang/website · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
module main

import net.http
import os
import sync
import time
import traffic
import veb

const port = 8082
const visit_cookie_name = 'vlang_session_visit'
const contact_email = 'alexander@vlang.io'
const stats_access_header = 'X-Stats-Access'

pub struct App {
	veb.StaticHandler
mut:
	traffic       &traffic.Tracker = unsafe { nil }
	stats_traffic &traffic.Tracker = unsafe { nil }
	traffic_lock  sync.Mutex
}

pub struct Context {
	veb.Context
mut:
	lang Lang
}

enum Lang {
	en
	ru
	es
	fr
	ja
	zh
	tr
	pt_br
	// cn
	// pt
}

fn (lang Lang) str() string {
	return match lang {
		.en { 'en' }
		.ru { 'ru' }
		.es { 'es' }
		.fr { 'fr' }
		.ja { 'ja' }
		.zh { 'zh' }
		.tr { 'tr' }
		.pt_br { 'pt-br' }
	}
}

fn lang_from_code(code string) ?Lang {
	return match code {
		'en' { .en }
		'ru' { .ru }
		'es' { .es }
		'fr' { .fr }
		'ja' { .ja }
		'zh' { .zh }
		'tr' { .tr }
		'pt-br' { .pt_br }
		else { none }
	}
}

// pub fn (app App) before_request() {
// println('[web] before_request: ${app.req.method} ${app.req.url}')
//}

fn main() {
	conninfo := os.getenv('VLANG_DB_CONNINFO')
	mut app := &App{}
	if conninfo != '' {
		app.traffic = traffic.new(traffic.Config{
			conninfo: conninfo
			site_id:  'vlang.io'
		}) or { panic('Could not initialise traffic tracking: ${err}') }
		app.stats_traffic = traffic.new(traffic.Config{
			conninfo: conninfo
			site_id:  'vlang.io'
		}) or { panic('Could not initialise traffic statistics: ${err}') }
	} else {
		eprintln('Traffic tracking is disabled (set VLANG_DB_CONNINFO to enable it).')
	}
	app.static_mime_types['.vtt'] = 'text/vtt; charset=utf-8'
	// app.serve_static('/favicon.ico', 'src/assets/favicon.ico')
	// makes all static files available.
	app.mount_static_folder_at(os.resource_abs_path('static'), '/')!
	/*
	app.mount_static_folder_at(os.resource_abs_path('.'), '/') or {
		println(err)
		return
	}
	*/

	veb.run_at[App, Context](mut app, host: 'localhost', port: port, family: .ip) or {
		panic('Failed to start Veb server: ${err}')
	}
}

pub fn (mut app App) index(mut ctx Context) veb.Result {
	ctx.set_lang() // TODO use middleware
	user_agent := ctx.req.header.get(.user_agent) or { '' }
	if traffic.is_bot_request(user_agent, ctx.req.url) {
		// Crawlers do not reliably retain cookies, so preserve each event while
		// the tracker keeps it out of the human totals.
		app.record_home_visit(ctx)
	} else if ctx.get_cookie(visit_cookie_name) == none {
		// Count at most once per browser session. The cookie is never stored.
		app.record_home_visit(ctx)
		ctx.set_cookie(http.Cookie{
			name:      visit_cookie_name
			value:     '1'
			path:      '/'
			secure:    true
			http_only: true
			same_site: .same_site_lax_mode
		})
	}

	return $veb.html('index.html')
}

@['/compare']
pub fn (mut app App) compare(mut ctx Context) veb.Result {
	ctx.set_lang()
	return $veb.html('templates/compare.html')
}

@['/utc_now']
pub fn (mut app App) utc_now(mut ctx Context) veb.Result {
	return ctx.text(time.now().unix().str())
}

@['/stats228']
pub fn (mut app App) stats228(mut ctx Context) veb.Result {
	access_token := os.getenv('VLANG_STATS_TOKEN')
	provided_token := ctx.req.header.get_custom(stats_access_header) or { '' }
	if access_token == '' || provided_token != access_token {
		ctx.res.set_status(.forbidden)
		return ctx.text('Forbidden')
	}
	if app.stats_traffic == unsafe { nil } {
		ctx.res.set_status(.service_unavailable)
		return ctx.html('<!doctype html><title>Traffic statistics unavailable</title><p>Traffic statistics are disabled for this local server.</p>')
	}
	return ctx.html(app.stats_traffic.stats_html(ctx.req.url, traffic.PageConfig{
		site_name:  'V'
		page_title: 'V traffic statistics'
		home_url:   '/'
		stats_path: '/stats228'
	}))
}

fn (mut app App) record_home_visit(ctx Context) {
	if app.traffic == unsafe { nil } {
		return
	}
	// Veb serves requests concurrently, while each tracker owns one PostgreSQL
	// connection. Traffic collection must never hold up page delivery.
	if !app.traffic_lock.try_lock() {
		return
	}
	defer {
		app.traffic_lock.unlock()
	}
	app.traffic.record(traffic.Request{
		url:        ctx.req.url
		referer:    ctx.get_header(.referer) or { '' }
		user_agent: ctx.req.header.get(.user_agent) or { '' }
		country:    ctx.get_custom_header('CF-IPCountry') or { '' }
	}) or { eprintln('Could not record page visit: ${err}') }
}

pub fn (mut ctx Context) set_lang() {
	code := ctx.get_cookie('lang') or { 'en' }
	ctx.lang = lang_from_code(code) or { Lang.en }
}

fn build_tr_menu(cur_lang Lang) string {
	// mut sb := strings.new_builder()
	// sb.write_string('<select>')
	// TODO loop when more languages are added
	s := '<select id=select_lang>' +
		'<option value=en ${if cur_lang == .en { 'selected' } else { '' }}>EN</option>' +
		'<option value=ru ${if cur_lang == .ru { 'selected' } else { '' }}>РУ</option>' +
		'<option value=es ${if cur_lang == .es { 'selected' } else { '' }}>ES</option>' +
		'<option value=fr ${if cur_lang == .fr { 'selected' } else { '' }}>FR</option>' +
		'<option value=ja ${if cur_lang == .ja { 'selected' } else { '' }}>日本語</option>' +
		'<option value=zh ${if cur_lang == .zh { 'selected' } else { '' }}>中文</option>' +
		'<option value=tr ${if cur_lang == .tr { 'selected' } else { '' }}>TR</option>' +
		'<option value=pt-br ${if cur_lang == .pt_br { 'selected' } else { '' }}>PT-BR</option></select>'
	/*
	s := match cur_lang {
		.ru { 'English' }
		.en { 'Русский' }
	}
	*/
	return s
}

@['/change_lang/:lang'; post]
pub fn (mut app App) change_lang(mut ctx Context, lang string) veb.Result {
	selected_lang := lang_from_code(lang) or {
		ctx.res.set_status(.bad_request)
		return ctx.json('Unsupported language')
	}
	expire_date := time.now().add_days(400)
	ctx.set_cookie(
		name:      'lang'
		value:     selected_lang.str()
		path:      '/'
		expires:   expire_date
		same_site: .same_site_lax_mode
	)
	// return ctx.redirect('/')
	return ctx.json('ok')
}