|
| 1 | +-- | |
| 2 | +-- Module : XMonad.Actions.ToggleFullFloat |
| 3 | +-- Description : Fullscreen (float) a window while remembering its original state. |
| 4 | +-- Copyright : (c) 2022 Tomáš Janoušek <[email protected]> |
| 5 | +-- License : BSD3 |
| 6 | +-- Maintainer : Tomáš Janoušek <[email protected]> |
| 7 | +-- |
| 8 | +module XMonad.Actions.ToggleFullFloat ( |
| 9 | + -- * Usage |
| 10 | + -- $usage |
| 11 | + toggleFullFloatEwmhFullscreen, |
| 12 | + toggleFullFloat, |
| 13 | + fullFloat, |
| 14 | + unFullFloat, |
| 15 | + gcToggleFullFloat, |
| 16 | + ) where |
| 17 | + |
| 18 | +import qualified Data.Map.Strict as M |
| 19 | + |
| 20 | +import XMonad |
| 21 | +import XMonad.Prelude |
| 22 | +import XMonad.Hooks.EwmhDesktops (setEwmhFullscreenHooks) |
| 23 | +import XMonad.Hooks.ManageHelpers |
| 24 | +import qualified XMonad.StackSet as W |
| 25 | +import qualified XMonad.Util.ExtensibleState as XS |
| 26 | + |
| 27 | +-- --------------------------------------------------------------------- |
| 28 | +-- $usage |
| 29 | +-- |
| 30 | +-- The main use-case is to make 'ewmhFullscreen' (re)store the size and |
| 31 | +-- position of floating windows instead of just unconditionally sinking them |
| 32 | +-- into the floating layer. To enable this, you'll need this in your |
| 33 | +-- @xmonad.hs@: |
| 34 | +-- |
| 35 | +-- > import XMonad |
| 36 | +-- > import XMonad.Actions.ToggleFullFloat |
| 37 | +-- > import XMonad.Hooks.EwmhDesktops |
| 38 | +-- > |
| 39 | +-- > main = xmonad $ … . toggleFullFloatEwmhFullscreen . ewmhFullscreen . ewmh . … $ def{…} |
| 40 | +-- |
| 41 | +-- Additionally, this "smart" fullscreening can be bound to a key and invoked |
| 42 | +-- manually whenever one needs a larger window temporarily: |
| 43 | +-- |
| 44 | +-- > , ((modMask .|. shiftMask, xK_t), withFocused toggleFullFloat) |
| 45 | + |
| 46 | +newtype ToggleFullFloat = ToggleFullFloat{ fromToggleFullFloat :: M.Map Window (Maybe W.RationalRect) } |
| 47 | + deriving (Show, Read) |
| 48 | + |
| 49 | +instance ExtensionClass ToggleFullFloat where |
| 50 | + extensionType = PersistentExtension |
| 51 | + initialValue = ToggleFullFloat mempty |
| 52 | + |
| 53 | +-- | Full-float a window, remembering its state (tiled/floating and |
| 54 | +-- position/size). |
| 55 | +fullFloat :: Window -> X () |
| 56 | +fullFloat = windows . appEndo <=< runQuery doFullFloatSave |
| 57 | + |
| 58 | +-- | Restore window to its remembered state. |
| 59 | +unFullFloat :: Window -> X () |
| 60 | +unFullFloat = windows . appEndo <=< runQuery doFullFloatRestore |
| 61 | + |
| 62 | +-- | Full-float a window, if it's not already full-floating. Otherwise, |
| 63 | +-- restore its original state. |
| 64 | +toggleFullFloat :: Window -> X () |
| 65 | +toggleFullFloat w = ifM (isFullFloat w) (unFullFloat w) (fullFloat w) |
| 66 | + |
| 67 | +isFullFloat :: Window -> X Bool |
| 68 | +isFullFloat w = gets $ (Just fullRect ==) . M.lookup w . W.floating . windowset |
| 69 | + where |
| 70 | + fullRect = W.RationalRect 0 0 1 1 |
| 71 | + |
| 72 | +doFullFloatSave :: ManageHook |
| 73 | +doFullFloatSave = do |
| 74 | + w <- ask |
| 75 | + liftX $ do |
| 76 | + f <- gets $ M.lookup w . W.floating . windowset |
| 77 | + -- @M.insertWith const@ = don't overwrite stored original state |
| 78 | + XS.modify' $ ToggleFullFloat . M.insertWith const w f . fromToggleFullFloat |
| 79 | + doFullFloat |
| 80 | + |
| 81 | +doFullFloatRestore :: ManageHook |
| 82 | +doFullFloatRestore = do |
| 83 | + w <- ask |
| 84 | + mf <- liftX $ do |
| 85 | + mf <- XS.gets $ M.lookup w . fromToggleFullFloat |
| 86 | + XS.modify' $ ToggleFullFloat . M.delete w . fromToggleFullFloat |
| 87 | + pure mf |
| 88 | + doF $ case mf of |
| 89 | + Just (Just f) -> W.float w f -- was floating before |
| 90 | + Just Nothing -> W.sink w -- was tiled before |
| 91 | + Nothing -> W.sink w -- fallback when not found in ToggleFullFloat |
| 92 | + |
| 93 | +-- | Install ToggleFullFloat garbage collection hooks. |
| 94 | +-- |
| 95 | +-- Note: This is included in 'toggleFullFloatEwmhFullscreen', only needed if |
| 96 | +-- using the 'toggleFullFloat' separately from the EWMH hook. |
| 97 | +gcToggleFullFloat :: XConfig a -> XConfig a |
| 98 | +gcToggleFullFloat c = c { startupHook = startupHook c <> gcToggleFullFloatStartupHook |
| 99 | + , handleEventHook = handleEventHook c <> gcToggleFullFloatEventHook } |
| 100 | + |
| 101 | +-- | ToggleFullFloat garbage collection: drop windows when they're destroyed. |
| 102 | +gcToggleFullFloatEventHook :: Event -> X All |
| 103 | +gcToggleFullFloatEventHook DestroyWindowEvent{ev_window = w} = do |
| 104 | + XS.modify' $ ToggleFullFloat . M.delete w . fromToggleFullFloat |
| 105 | + mempty |
| 106 | +gcToggleFullFloatEventHook _ = mempty |
| 107 | + |
| 108 | +-- | ToggleFullFloat garbage collection: restrict to existing windows at |
| 109 | +-- startup. |
| 110 | +gcToggleFullFloatStartupHook :: X () |
| 111 | +gcToggleFullFloatStartupHook = withWindowSet $ \ws -> |
| 112 | + XS.modify' $ ToggleFullFloat . M.filterWithKey (\w _ -> w `W.member` ws) . fromToggleFullFloat |
| 113 | + |
| 114 | +-- | Hook this module into 'XMonad.Hooks.EwmhDesktops.ewmhFullscreen'. This |
| 115 | +-- makes windows restore their original state (size and position if floating) |
| 116 | +-- instead of unconditionally sinking into the tiling layer. |
| 117 | +-- |
| 118 | +-- ('gcToggleFullFloat' is included here.) |
| 119 | +toggleFullFloatEwmhFullscreen :: XConfig a -> XConfig a |
| 120 | +toggleFullFloatEwmhFullscreen = |
| 121 | + setEwmhFullscreenHooks doFullFloatSave doFullFloatRestore . |
| 122 | + gcToggleFullFloat |
0 commit comments